Help with VBA code for auto filter cells with no highligths

[usui]

Hi,

Can anyone help me with a vba code for auto filtering the cells with no highlights on Columns A & B and result should be on cell E36 separated with comma.
(I am separating the datas with no duplicates "columns A&B")

please see the sample here:

I hope someone will be able to help me with this problem. I really appreciate any help I can get.

 

[Joe4]

How exactly are these cells being colored?
Is it being done manually or by Conditional Formatting?
If Conditional Formatting, can you show us the exact rule that is doing the formatting?

 

[usui]

How exactly are these cells being colored?
Is it being done manually or by Conditional Formatting?
If Conditional Formatting, can you show us the exact rule that is doing the formatting?

Yes from conditional formatting, highlight duplicates..i want to have the datas with no duplicates (column a&b) separated with comma on cell E36

 

[Joe4]

Try this:

Sub MyNonDups()

    Dim lrA As Long, lrB As Long
    Dim r As Long
    Dim str As String
    
'   Find last row with values in columns A and B
    lrA = Cells(Rows.Count, "A").End(xlUp).Row
    lrB = Cells(Rows.Count, "B").End(xlUp).Row
    
'   Loop through all rows in columns A
    For r = 1 To lrA
'       If no duplicates, add to string
        If Application.WorksheetFunction.CountIf(Range("A:B"), Cells(r, "A")) = 1 Then
            str = str & Cells(r, "A") & ", "
        End If
    Next r
    
'   Loop through all rows in columns B
    For r = 1 To lrB
'       If no duplicates, add to string
        If Application.WorksheetFunction.CountIf(Range("A:B"), Cells(r, "B")) = 1 Then
            str = str & Cells(r, "B") & ", "
        End If
    Next r
    
'   If any values returned, enter to cell E36
    If Len(str) > 0 Then Range("E36") = Left(str, Len(str) - 2)
    
End Sub