How do you code in VBA to conditionally select and copy certain data from one range to another?

[turner737]

Hello,

I have a table of data where i want to select data that meet a certain criteria and copy and paste that to a table in another range.

I.e. I have a table with 6 columns. The first column is date and that is what i am using as a condition. If the date for a given row is in the past week then i want to take the value from columns 2, 3, and 4 from that row and copy paste their values into a table on another sheet.

I've dimensionalised the ranges for each column, but im not sure how to go about going through each row to look at the date and then copy paste the data from the other columns if that date was in the past week.

Can someone assist?!

Much appreciated.

 

[Michael M]

Maybe something like this
This will do the search on the active sheet and copy the range to the last row + 1 on Sheet2 in column "A"

Sub MM1()
Dim lr As Long, lr2 As Long, r As Long
lr = Cells(Rows.Count, "A").End(xlUp).Row
lr2 = Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Row
For r = lr To 1 Step -1
    If Range("A" & r).Value <= Date And Range("A" & r).Value >= Date - 7 Then
        Range("B" & r & ":D" & r).Copy Sheets("Sheet2").Range("A" & lr2 + 1)
        lr2 = Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Row
    End If
Next r
End Sub

 

[turner737]

Many thanks for the quick response. This was very helpful.

I'm working through this now and will provide any questions if they come up.

Thanks again.

 

[turner737]

You solved my first problem perfectly.

The follow up question being now if i wanted to cherry pick the columns and paste them into different columns on the other sheet how would that be done.

I.e. the data i need isnt actually in consecutive columns.

So, I need to take data from Column A & B posted to Column A & B on the next sheet. But, then i need data from column E to be pasted to column C on sheet 2 and column G on sheet 1 to column E on sheet 2.

Many thanks for your assistance.

 

[Michael M]

Try

Sub MM1()
Dim lr As Long, lr2 As Long, r As Long
lr = Cells(Rows.Count, "A").End(xlUp).Row
lr2 = Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Row
For r = lr To 1 Step -1
    If Range("A" & r).Value <= Date And Range("A" & r).Value >= Date - 7 Then
        Range("A" & r & ":B" & r).Copy Sheets("Sheet2").Range("A" & lr2 + 1)
        Range("E" & r).Copy Sheets("Sheet2").Range("C" & lr2 + 1)
        Range("G" & r).Copy Sheets("Sheet2").Range("E" & lr2 + 1)
        lr2 = Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Row
    End If
Next r
End Sub