How to extract list of entries by month & without duplicates.

[BigMoe]

***I'm using Excel 2003***

I'm working on a spreadsheet to track my stock trading activities for one year. I used the following formula to give me a list of all the stocks traded without duplicates:
=INDEX(D$5:D$4244,MATCH(0,COUNTIF(J$4:J4,D$5:D$4244),-1))

However, I'm having difficulty doing the same for a list of stocks traded by month without any duplicates. Basically, I need help in adding some sort of month component to the above formula, or a completely new formula that will do the trick. Below is a miniature mock-up of that portion of the spreadsheet.

Many thanks in advance.

C	D	E	F
Date Traded	Stock Symbols	Symbols - Jan	Symbols - Feb
1/1/15	AAPL	AAPL
1/1/15	RIG	RIG
1/1/15	XOM	XOM
1/1/15		FB
1/1/15		UNH
1/2/15	FB	TWTR
1/2/15	AAPL	VLO
1/2/15	RIG
1/2/15
1/2/15
1/3/15	UNH
1/3/15	AAPL
1/3/15	TWTR
1/3/15	VLO
1/3/15

<tbody>
</tbody>

 

[FDibbins]

Maybe Im missing something here, but why not just reference the jan column, instead of the Stock column?

 

[BigMoe]

The Jan column is the column I'm asking for help with. I'm just showing the results i would like to have.

 

[Weazel]

kind of complex but maybe with a couple of modifications to the table to just the month abbreviation.

I also believe that with 2003 you need to have the Analysis tool pack add in installed to access the frequency function but I could be mistaken.

Row 1 with the unique count for each month could be hidden if you wanted.

Below is a link to the sheet.

https://app.box.com/s/1bwvvnxz50jhstqrh8axut7si6h9h4gb


Excel 2012

	C	D	E	F	G
1		Unique Count	6	1	2
2	Date Traded	Stock Symbols	Jan	Feb	Mar
3	1/1/2015	AAPL	AAPL	RIG	AAPL
4	1/1/2015	RIG	RIG		TWTR
5	1/1/2015	XOM	XOM
6	1/1/2015		FB
7	1/1/2015		UNH
8	1/2/2015	FB	VLO
9	3/2/2015	AAPL
10	2/2/2015	RIG
11	1/2/2015
12	2/2/2015
13	1/3/2015	UNH
14	3/3/2015	AAPL
15	3/4/2015	TWTR
16	1/3/2015	VLO
17	1/3/2015

<tbody>
</tbody>

Sheet1​

Array Formulas Cell Formula E1 {=SUM(IF(FREQUENCY(IF($D$3:$D$17<>"",IF(TEXT($C$3:$C$17,"mmm")=E$2,MATCH($D$3:$D$17,$D$3:$D$17,0))),ROW(C$3:C$17)-ROW(C$3)+1),1))} E3 {=IF(ROWS(E$2:E2)>E$1,"",INDEX($D$3:$D$17,SMALL(IF(FREQUENCY(IF($D$3:$D$17<>"",IF(TEXT($C$3:$C$17,"mmm")=E$2,MATCH($D$3:$D$17,$D$3:$D$17,0))),ROW(C$3:C$17)-ROW(C$3)+1),ROW(C$3:C$17)-ROW(C$3)+1),ROWS(E$3:E3))))} <tbody> </tbody> Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter the {} manually yourself

<tbody>
</tbody>

 

[BigMoe]

Thanks so much Weazel!
You actually also solved my next question with your two formulas. Really appreciate it.