How to extract text between brackets but extracted text might have brackets as well

[bee5s4]

As the subject suggests, I'm trying to extract some text but seem to be spinning my wheels a little bit. I'm getting better at it but I'd definitely put myself in the novice category of Excel users.

The source text is in this format:
xxxx-xxxx (Some text here)
xxxx-xxxx (Some other text here(testing))

I want to extract the text between the outermost brackets and my current formula reads as follows:
=MID(L50,SEARCH("(",L50)+1,SEARCH(")",L50)-SEARCH("(",L50)-1)

This works for scenarios where the text has just the opening and closing bracket but when there's brackets embedded in the text, I get "some other text here(testing"

Is there a clean(er) way of doing this? Thank you in advance!

 

[bee5s4]

Making progress.....my updated formula reads as follows:
=IF(RIGHT(L58,2)="))",MID(L58,SEARCH("(",L58)+1,SEARCH(")",L58)-SEARCH("(",L58)),MID(L58,SEARCH("(",L58)+1,SEARCH(")",L58)-SEARCH("(",L58)-1))

However, I could see this breaking if the text looked like:
xxxx-xxxx (Some text here (testing) but more text here)

I'd love to hear suggestions on how this might be accomplished as I'm still learning about available functions and trying to apply "good" logic within spreadsheets.

 

[Tetra201]

See if the following formula works for you:

=MID(A1,FIND("(",A1)+1,FIND(CHAR(1),SUBSTITUTE(A1,")",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,")",""))))-FIND("(",A1)-1)

 

[Fluff]

Another option

Fluff.xlsm
	A	B
1
2	xxxx-xxxx (Some text here)	Some text here
3	xxxx-xxxx (Some other text here(testing))	Some other text here(testing)
4	xxxx-xxxx (Some text here (testing) but more text here)	Some text here (testing) but more text here
Data

Cell Formulas
Range	Formula
B2:B4	B2	=TEXTBEFORE(TEXTAFTER(A2,"(",1),")",-1)

 

[bee5s4]

You wizards!

Tetra201 - this did the trick so thank you for the quick help. I'll try to break the formula down to understand exactly what's happening and may circle back if I have questions.

Fluff - I'll try your suggestion later today and I like the simpler format. I assume textbefore/textafter are new(er) functions as I haven't encountered them in the past.

 

[Fluff]

I assume textbefore/textafter are new(er) functions

Yes they are, although if your on the semi-annual channel you may not have them yet.

 

[bee5s4]

Wound up not using it in this case as the end users don't utilize a recent version of Excel but I'll definitely be trying it out elsewhere. Seems like a simple solution to something that has long been a "clunky" formula.

Thank you both!

 

[Fluff]

Glad we could help & thanks for the feedback.