ID3 Editor

[GaryR]

Hey guys,
i have a very wierd question for you about something that has my curiosity.

I know that theres lots of VB6 code out there to let you read/write ID3 tags to MP3 files, does anyone know where i would go for some VBA code to do the same thing?

I'd be interested in being able to populate a spreadsheet with all the .mp3 files found in a specified directory with full Filename, and have columns that populate with artist, track, genre, year, etc...

then i could edit the spreadsheet. click a button to save the updated tags and have it save them.

if i can just find the code to read/write the tags, i'll try putting the experiement together. or if someone knows of a solution kinda like this already? that'd be sweet.

 

[GaryR]

I found this code, but it supports ID3 v1 only. i'm hoping someone knows how to modify this to support up to at least ID3 v2.3. although it does seem to pull info from 2.3 files, i haven't tested it much and of course the 2.3 fields aren't available to edit with this code.

i'll include the sub i wrote that populates a worksheet to.

first, this goes into a CLASS module named "clsMp3TagV1"

''' START CODE '''
'Place this code into a CLASS module and name it "clsMp3TagV1"
Private Type MP3ID3V1Tag
    tag As String * 3
    Title As String * 30
    Artist As String * 30
    Album As String * 30
    Year As String * 4
    Comment As String * 28
    Filler As Byte
    Track As Byte
    Genre As Byte
End Type
'
Private m_sMp3File As String
Private m_bHasID3v1Tag As Boolean
'
Private m_sTag As String
Private m_sTitle As String
Private m_sArtist As String
Private m_sAlbum As String
Private m_sYear As String
Private m_sComment As String
Private m_sGenre As Byte
Private m_sTrack As Byte
Public Property Get MP3File() As String
    MP3File = m_sMp3File
End Property
Public Property Let MP3File(ByVal value As String)
    m_sMp3File = value
    pLoadTag
End Property
Public Sub Update()
    pUpdateTag
End Sub
Public Property Get HasID3v1Tag() As Boolean
    HasID3v1Tag = m_bHasID3v1Tag
End Property
Public Property Get Title() As String
    Title = RTrimZ(m_sTitle)
End Property
Public Property Let Title(ByVal value As String)
    m_sTitle = value
End Property
Public Property Get Artist() As String
    Artist = RTrimZ(m_sArtist)
End Property
Public Property Let Artist(ByVal value As String)
    m_sArtist = value
End Property
Public Property Get Album() As String
    Album = RTrimZ(m_sAlbum)
End Property
Public Property Let Album(ByVal value As String)
    m_sAlbum = value
End Property
Public Property Get Year() As String
    Year = RTrimZ(m_sYear)
End Property
Public Property Let Year(ByVal value As String)
    m_sYear = value
End Property
Public Property Get Track() As Byte
'Track = RTrimZ(m_sTrack)
    Track = m_sTrack
End Property
Public Property Let Track(ByVal value As Byte)
    m_sTrack = value
End Property
Public Property Get Comment() As String
    Comment = RTrimZ(m_sComment)
End Property
Public Property Let Comment(ByVal value As String)
    m_sComment = value
End Property
Public Property Get Genre() As Byte
    Genre = m_sGenre
End Property
Public Property Let Genre(ByVal value As Byte)
    m_sGenre = value
End Property
Public Property Get GenreName(ByVal Genre As Byte) As String
    Select Case Genre
        Case 34: GenreName = "Acid"
        Case 74: GenreName = "Acid Jazz"
        Case 73: GenreName = "Acid Punk"
        Case 99: GenreName = "Acoustic"
        Case 40: GenreName = "Alt.Rock"
        Case 20: GenreName = "Alternative"
        Case 26: GenreName = "Ambient"
        Case 145: GenreName = "Anime"
        Case 90: GenreName = "Avant Garde"
        Case 116: GenreName = "Ballad"
        Case 41: GenreName = "Bass"
        Case 135: GenreName = "Beat"
        Case 85: GenreName = "Bebob"
        Case 96: GenreName = "Big Band"
        Case 138: GenreName = "Black Metal"
        Case 89: GenreName = "Blue Grass"
        Case 0: GenreName = "Blues"
        Case 107: GenreName = "Booty Bass"
        Case 132: GenreName = "Brit Pop"
        Case 65: GenreName = "Cabaret"
        Case 88: GenreName = "Celtic"
        Case 104: GenreName = "Chamber Music"
        Case 102: GenreName = "Chanson"
        Case 97: GenreName = "Chorus"
        Case 136: GenreName = "Christian Gangsta Rap"
        Case 61: GenreName = "Christian Rap"
        Case 141: GenreName = "Christian Rock"
        Case 1: GenreName = "Classic Rock"
        Case 32: GenreName = "Classical"
        Case 112: GenreName = "Club"
        Case 128: GenreName = "Club - House"
        Case 57: GenreName = "Comedy"
        Case 140: GenreName = "Contemporary Christian"
        Case 2: GenreName = "Country"
        Case 139: GenreName = "Crossover"
        Case 58: GenreName = "Cult"
        Case 3: GenreName = "Dance"
        Case 125: GenreName = "Dance Hall"
        Case 50: GenreName = "Darkwave"
        Case 22: GenreName = "Death Metal"
        Case 4: GenreName = "Disco"
        Case 55: GenreName = "Dream"
        Case 127: GenreName = "Drum & Bass"
        Case 122: GenreName = "Drum Solo"
        Case 120: GenreName = "Duet"
        Case 98: GenreName = "Easy Listening"
        Case 52: GenreName = "Electronic"
        Case 48: GenreName = "Ethnic"
        Case 54: GenreName = "Eurodance"
        Case 124: GenreName = "Euro - House"
        Case 25: GenreName = "Euro - Techno"
        Case 84: GenreName = "Fast Fusion"
        Case 80: GenreName = "Folk"
        Case 81: GenreName = "Folk / Rock"
        Case 115: GenreName = "Folklore"
        Case 119: GenreName = "Freestyle"
        Case 5: GenreName = "Funk"
        Case 30: GenreName = "Fusion"
        Case 36: GenreName = "Game"
        Case 59: GenreName = "Gangsta Rap"
        Case 126: GenreName = "Goa"
        Case 38: GenreName = "Gospel"
        Case 49: GenreName = "Gothic"
        Case 91: GenreName = "Gothic Rock"
        Case 6: GenreName = "Grunge"
        Case 79: GenreName = "Hard Rock"
        Case 129: GenreName = "Hardcore"
        Case 137: GenreName = "Heavy Metal"
        Case 7: GenreName = "Hip Hop"
        Case 35: GenreName = "House"
        Case 100: GenreName = "Humour"
        Case 131: GenreName = "Indie"
        Case 19: GenreName = "Industrial"
        Case 33: GenreName = "Instrumental"
        Case 46: GenreName = "Instrumental Pop"
        Case 47: GenreName = "Instrumental Rock"
        Case 8: GenreName = "Jazz"
        Case 29: GenreName = "Jazz - Funk"
        Case 146: GenreName = "JPop"
        Case 63: GenreName = "Jungle"
        Case 86: GenreName = "Latin"
        Case 71: GenreName = "Lo - fi"
        Case 45: GenreName = "Meditative"
        Case 142: GenreName = "Merengue"
        Case 9: GenreName = "Metal"
        Case 77: GenreName = "Musical"
        Case 82: GenreName = "National Folk"
        Case 64: GenreName = "Native American"
        Case 133: GenreName = "Negerpunk"
        Case 10: GenreName = "New Age"
        Case 66: GenreName = "New Wave"
        Case 39: GenreName = "Noise"
        Case 11: GenreName = "Oldies"
        Case 103: GenreName = "Opera"
        Case 12: GenreName = "Other"
        Case 75: GenreName = "Polka"
        Case 134: GenreName = "Polsk Punk"
        Case 13: GenreName = "Pop"
        Case 62: GenreName = "Pop / Funk"
        Case 53: GenreName = "Pop / Folk"
        Case 109: GenreName = "**** Groove"
        Case 117: GenreName = "Power Ballad"
        Case 23: GenreName = "Pranks"
        Case 108: GenreName = "Primus"
        Case 92: GenreName = "Progressive Rock"
        Case 67: GenreName = "Psychedelic"
        Case 93: GenreName = "Psychedelic Rock"
        Case 43: GenreName = "Punk"
        Case 121: GenreName = "Punk Rock"
        Case 14: GenreName = "R&B"
        Case 15: GenreName = "Rap"
        Case 68: GenreName = "Rave"
        Case 16: GenreName = "Reggae"
        Case 76: GenreName = "Retro"
        Case 87: GenreName = "Revival"
        Case 118: GenreName = "Rhythmic Soul"
        Case 17: GenreName = "Rock"
        Case 78: GenreName = "Rock 'n'Roll"
        Case 143: GenreName = "Salsa"
        Case 114: GenreName = "Samba"
        Case 110: GenreName = "Satire"
        Case 69: GenreName = "Showtunes"
        Case 21: GenreName = "Ska"
        Case 111: GenreName = "Slow Jam"
        Case 95: GenreName = "Slow Rock"
        Case 105: GenreName = "Sonata"
        Case 42: GenreName = "Soul"
        Case 37: GenreName = "Sound Clip"
        Case 24: GenreName = "Soundtrack"
        Case 56: GenreName = "Southern Rock"
        Case 44: GenreName = "Space"
        Case 101: GenreName = "Speech"
        Case 83: GenreName = "Swing"
        Case 94: GenreName = "Symphonic Rock"
        Case 106: GenreName = "Symphony"
        Case 147: GenreName = "Synth Pop"
        Case 113: GenreName = "Tango"
        Case 18: GenreName = "Techno"
        Case 51: GenreName = "Techno - Industrial"
        Case 130: GenreName = "Terror"
        Case 144: GenreName = "Thrash Metal"
        Case 60: GenreName = "Top 40"
        Case 70: GenreName = "Trailer"
        Case 31: GenreName = "Trance"
        Case 72: GenreName = "Tribal"
        Case 27: GenreName = "Trip Hop"
        Case 28: GenreName = "Vocal"
    End Select
End Property
Private Sub pLoadTag()
Dim lErr As Long
Dim sErr As String
    m_bHasID3v1Tag = False
    m_sComment = ""
    m_sArtist = ""
    m_sAlbum = ""
    m_sYear = ""
    m_sGenre = 255
    m_sTitle = ""
    m_sTrack = 0
    f% = FreeFile
    On Error Resume Next
    Open m_sMp3File For Binary Access Read Lock Write As #f%
    If (Err.Number <> 0) Then
        lErr = Err.Number
        sErr = Err.Description
        On Error GoTo 0
        Err.Raise lErr, "clsMp3TagV1", sErr
    Else
        On Error GoTo 0
        If LOF(f%) > 128 Then
            Dim tag As MP3ID3V1Tag
            Get #f%, LOF(f%) - 127, tag.tag
            If Not (StrComp(tag.tag, "TAG") = 0) Then
                ' no tag
            Else
                m_bHasID3v1Tag = True
                Get #f%, , tag.Title
                Get #f%, , tag.Artist
                Get #f%, , tag.Album
                Get #f%, , tag.Year
                Get #f%, , tag.Comment
                Get #f%, , tag.Filler
                Get #f%, , tag.Track
                Get #f%, , tag.Genre
                m_sTitle = tag.Title
                m_sArtist = tag.Artist
                m_sAlbum = tag.Album
                m_sYear = tag.Year
                m_sComment = tag.Comment
                m_sTrack = tag.Track
                m_sGenre = tag.Genre
            End If
        End If
    End If
    On Error Resume Next
    Close #f%
    On Error GoTo 0
    Err.Clear
End Sub
Private Sub pUpdateTag()
Dim f As Integer
Dim lErr As Long
Dim sErr As String
    f = FreeFile
    On Error Resume Next
    Open m_sMp3File For Binary Access Read Write Lock Write As #f
    If (Err.Number <> 0) Then
        lErr = Err.Number
        sErr = Err.Description
        On Error GoTo 0
        Err.Raise lErr, "clsMp3TagV1", sErr
    Else
        Dim tag As MP3ID3V1Tag
        If LOF(f) > 0 Then
            If LOF(f) > 128 Then
                Get #f, LOF(f) - 127, tag.tag
                If Not (StrComp(tag.tag, "TAG") = 0) Then
                    ' no MP3 tag already, need to extend the file
                    ' to add it
                    Seek #f, LOF(f)
                    tag.tag = "TAG"
                    Put #f, , tag.tag
                End If
                LSet tag.Title = m_sTitle
                LSet tag.Artist = m_sArtist
                LSet tag.Album = m_sAlbum
                LSet tag.Year = m_sYear
                tag.Track = m_sTrack
                LSet tag.Comment = m_sComment
                tag.Genre = m_sGenre
                Put #f, , tag.Title
                Put #f, , tag.Artist
                Put #f, , tag.Album
                Put #f, , tag.Year
                Put #f, , tag.Comment
                Put #f, , tag.Filler
                Put #f, , tag.Track
                Put #f, , tag.Genre
            End If
        Else
            On Error Resume Next
            Close #f
            On Error GoTo 0
            Err.Raise vbObjectError + 1, "clsMp3TagV1", m_sMp3File & " is not a valid MP3 file."
        End If
    End If
    On Error Resume Next
    Close #f
    On Error GoTo 0
    Err.Clear
End Sub
Private Function RTrimZ(s As String) As String
Dim p As Long
    '
    p = InStr(1, s, Chr(0))
    If p Then
        RTrimZ = RTrim(Left(s, p - 1))
    Else
        RTrimZ = RTrim(s)
    End If
End Function
''' END CODE '''

then this into a regular module to use it:
I added the function to do a GenreLookup by pulling info from his code (the .GenreName attribute doesn't seem to work in his code.) I also wrote the aquire_files sub to populate a worksheet with the ID3 info (so that it may be edited and later written back to the file)

'Name the class clsMp3TagV1, and use it like this:
Sub testMp3Tag()
Dim tag As clsMp3TagV1, sav As String
    Set tag = New clsMp3TagV1
    With tag
        .MP3File = "D:\Bad.mp3"
Debug.Print .Artist; " Album: "; .Album; " Title: "; .Title; " Genre #: "; .Genre; " Track # "; .Track; " Year: "; .Year; " Comment: "; .Comment
        sav = .Artist                  'Save current Artist name
        .Artist = "Stuart McCall"
        .Update                        'Change name
Debug.Print .Artist; " - "; .Album; " - "; .Title
        .Artist = sav
        .Update                        'Restore original name
Debug.Print .Artist; " - "; .Album; " - "; .Title
    End With
    Set tag = Nothing
End Sub
'Replacing "D:\Bad.mp3" with your file path.
 
 
Sub aquire_files()
Dim openFile, a As Integer, tag As clsMp3TagV1
    Set tag = New clsMp3TagV1
    openFile = Application.GetOpenFilename("MP3s (*.mp3), *.mp3", , "Choose file to open", , True)
    Worksheets.Add
    Cells(1, 1).value = "FileName"
    Cells(1, 2).value = "Artist"
    Cells(1, 3).value = "Album"
    Cells(1, 4).value = "Title"
    Cells(1, 5).value = "Genre #"
    Cells(1, 6).value = "Genre"
    Cells(1, 7).value = "Track #"
    Cells(1, 8).value = "Year"
    Cells(1, 9).value = "Comment"
    For a = 1 To UBound(openFile)
        Cells(a + 1, 1).value = openFile(a)
        With tag
            .MP3File = Cells(a, 1).value
            Cells(a + 1, 2).value = .Artist
            Cells(a + 1, 3).value = .Album
            Cells(a + 1, 4).value = .Title
            Cells(a + 1, 5).value = .Genre
            Cells(a + 1, 6).value = GenreLookup(.Genre)
            Cells(a + 1, 7).value = .Track
            Cells(a + 1, 8).value = .Year
            Cells(a + 1, 9).value = .Comment
        End With
    Next a
End Sub
 
 
Function GenreLookup(GenreNumber)
    Select Case GenreNumber
        Case 34: GenreLookup = "Acid"
        Case 74: GenreLookup = "Acid Jazz"
        Case 73: GenreLookup = "Acid Punk"
        Case 99: GenreLookup = "Acoustic"
        Case 40: GenreLookup = "Alt.Rock"
        Case 20: GenreLookup = "Alternative"
        Case 26: GenreLookup = "Ambient"
        Case 145: GenreLookup = "Anime"
        Case 90: GenreLookup = "Avant Garde"
        Case 116: GenreLookup = "Ballad"
        Case 41: GenreLookup = "Bass"
        Case 135: GenreLookup = "Beat"
        Case 85: GenreLookup = "Bebob"
        Case 96: GenreLookup = "Big Band"
        Case 138: GenreLookup = "Black Metal"
        Case 89: GenreLookup = "Blue Grass"
        Case 0: GenreLookup = "Blues"
        Case 107: GenreLookup = "Booty Bass"
        Case 132: GenreLookup = "Brit Pop"
        Case 65: GenreLookup = "Cabaret"
        Case 88: GenreLookup = "Celtic"
        Case 104: GenreLookup = "Chamber Music"
        Case 102: GenreLookup = "Chanson"
        Case 97: GenreLookup = "Chorus"
        Case 136: GenreLookup = "Christian Gangsta Rap"
        Case 61: GenreLookup = "Christian Rap"
        Case 141: GenreLookup = "Christian Rock"
        Case 1: GenreLookup = "Classic Rock"
        Case 32: GenreLookup = "Classical"
        Case 112: GenreLookup = "Club"
        Case 128: GenreLookup = "Club - House"
        Case 57: GenreLookup = "Comedy"
        Case 140: GenreLookup = "Contemporary Christian"
        Case 2: GenreLookup = "Country"
        Case 139: GenreLookup = "Crossover"
        Case 58: GenreLookup = "Cult"
        Case 3: GenreLookup = "Dance"
        Case 125: GenreLookup = "Dance Hall"
        Case 50: GenreLookup = "Darkwave"
        Case 22: GenreLookup = "Death Metal"
        Case 4: GenreLookup = "Disco"
        Case 55: GenreLookup = "Dream"
        Case 127: GenreLookup = "Drum & Bass"
        Case 122: GenreLookup = "Drum Solo"
        Case 120: GenreLookup = "Duet"
        Case 98: GenreLookup = "Easy Listening"
        Case 52: GenreLookup = "Electronic"
        Case 48: GenreLookup = "Ethnic"
        Case 54: GenreLookup = "Eurodance"
        Case 124: GenreLookup = "Euro - House"
        Case 25: GenreLookup = "Euro - Techno"
        Case 84: GenreLookup = "Fast Fusion"
        Case 80: GenreLookup = "Folk"
        Case 81: GenreLookup = "Folk / Rock"
        Case 115: GenreLookup = "Folklore"
        Case 119: GenreLookup = "Freestyle"
        Case 5: GenreLookup = "Funk"
        Case 30: GenreLookup = "Fusion"
        Case 36: GenreLookup = "Game"
        Case 59: GenreLookup = "Gangsta Rap"
        Case 126: GenreLookup = "Goa"
        Case 38: GenreLookup = "Gospel"
        Case 49: GenreLookup = "Gothic"
        Case 91: GenreLookup = "Gothic Rock"
        Case 6: GenreLookup = "Grunge"
        Case 79: GenreLookup = "Hard Rock"
        Case 129: GenreLookup = "Hardcore"
        Case 137: GenreLookup = "Heavy Metal"
        Case 7: GenreLookup = "Hip Hop"
        Case 35: GenreLookup = "House"
        Case 100: GenreLookup = "Humour"
        Case 131: GenreLookup = "Indie"
        Case 19: GenreLookup = "Industrial"
        Case 33: GenreLookup = "Instrumental"
        Case 46: GenreLookup = "Instrumental Pop"
        Case 47: GenreLookup = "Instrumental Rock"
        Case 8: GenreLookup = "Jazz"
        Case 29: GenreLookup = "Jazz - Funk"
        Case 146: GenreLookup = "JPop"
        Case 63: GenreLookup = "Jungle"
        Case 86: GenreLookup = "Latin"
        Case 71: GenreLookup = "Lo - fi"
        Case 45: GenreLookup = "Meditative"
        Case 142: GenreLookup = "Merengue"
        Case 9: GenreLookup = "Metal"
        Case 77: GenreLookup = "Musical"
        Case 82: GenreLookup = "National Folk"
        Case 64: GenreLookup = "Native American"
        Case 133: GenreLookup = "Negerpunk"
        Case 10: GenreLookup = "New Age"
        Case 66: GenreLookup = "New Wave"
        Case 39: GenreLookup = "Noise"
        Case 11: GenreLookup = "Oldies"
        Case 103: GenreLookup = "Opera"
        Case 12: GenreLookup = "Other"
        Case 75: GenreLookup = "Polka"
        Case 134: GenreLookup = "Polsk Punk"
        Case 13: GenreLookup = "Pop"
        Case 62: GenreLookup = "Pop / Funk"
        Case 53: GenreLookup = "Pop / Folk"
        Case 109: GenreLookup = "**** Groove"
        Case 117: GenreLookup = "Power Ballad"
        Case 23: GenreLookup = "Pranks"
        Case 108: GenreLookup = "Primus"
        Case 92: GenreLookup = "Progressive Rock"
        Case 67: GenreLookup = "Psychedelic"
        Case 93: GenreLookup = "Psychedelic Rock"
        Case 43: GenreLookup = "Punk"
        Case 121: GenreLookup = "Punk Rock"
        Case 14: GenreLookup = "R&B"
        Case 15: GenreLookup = "Rap"
        Case 68: GenreLookup = "Rave"
        Case 16: GenreLookup = "Reggae"
        Case 76: GenreLookup = "Retro"
        Case 87: GenreLookup = "Revival"
        Case 118: GenreLookup = "Rhythmic Soul"
        Case 17: GenreLookup = "Rock"
        Case 78: GenreLookup = "Rock 'n'Roll"
        Case 143: GenreLookup = "Salsa"
        Case 114: GenreLookup = "Samba"
        Case 110: GenreLookup = "Satire"
        Case 69: GenreLookup = "Showtunes"
        Case 21: GenreLookup = "Ska"
        Case 111: GenreLookup = "Slow Jam"
        Case 95: GenreLookup = "Slow Rock"
        Case 105: GenreLookup = "Sonata"
        Case 42: GenreLookup = "Soul"
        Case 37: GenreLookup = "Sound Clip"
        Case 24: GenreLookup = "Soundtrack"
        Case 56: GenreLookup = "Southern Rock"
        Case 44: GenreLookup = "Space"
        Case 101: GenreLookup = "Speech"
        Case 83: GenreLookup = "Swing"
        Case 94: GenreLookup = "Symphonic Rock"
        Case 106: GenreLookup = "Symphony"
        Case 147: GenreLookup = "Synth Pop"
        Case 113: GenreLookup = "Tango"
        Case 18: GenreLookup = "Techno"
        Case 51: GenreLookup = "Techno - Industrial"
        Case 130: GenreLookup = "Terror"
        Case 144: GenreLookup = "Thrash Metal"
        Case 60: GenreLookup = "Top 40"
        Case 70: GenreLookup = "Trailer"
        Case 31: GenreLookup = "Trance"
        Case 72: GenreLookup = "Tribal"
        Case 27: GenreLookup = "Trip Hop"
        Case 28: GenreLookup = "Vocal"
        Case Else: GenreLookup = "UnKnown"
    End Select
End Function

EDIT: i found this code here:
http://objectmix.com/ado-dao-rdo-rds/321168-how-do-i-change-mp3-id3-tag-using-vba-access.html

posted by username Stuart McCall

 

[GaryR]

in my aquire_files sub, one quick typo

change

With tag
            .MP3File = Cells(a, 1).value

to read

With tag
            .MP3File = Cells(a + 1, 1).value

 

[GaryR]

/bump