Insert Hyperlink

[tobyhutton1234]

Hi

I'm trying to work out how to insert a hyperlink using vba.

I have a form where a user will enter theor username.

Once they enter their username and clicked ok it will apper in the cell where the box appers.

Heres my code sao far.

Private Sub CommandButton1_Click()
    If Len(Me.CamUser & "") = 0 Then
        MsgBox "You enter your username before you continue.", vbInformation + vbOnly, "Username"
            Cancel = True
        Exit Sub
    Else
        ActiveCell.Value = ("http://website.com/default.asp?ID=" & CamUser)
        Unload Me
    End If
End Sub

CamUser is the name of the textbox. I need the text to display in the cell to say (whatever their username) and a link to take them to a website.

Any ideas thanks.

 

[Jerry Sullivan]

Try something like:

Private Sub CommandButton1_Click()
    If Len(Me.CamUser.value & "") = 0 Then
        MsgBox "You enter your username before you continue.", _
            vbInformation + vbOKOnly
        Exit Sub
    End If
 
    With ActiveSheet
        .Hyperlinks.Add Anchor:=.Range("D4"), Address:= _
            "http://website.com/default.asp?ID=" & Me.CamUser.value, _
             TextToDisplay:=  Me.CamUser.value
        Unload Me
    End With
End Sub

You might want to consider using a Cell Address and possibly an explicit SheetName reference. Unless you are controlling ActiveCell in your code, the link will be placed in whatever cell happened to be active when the userform was opened. Might possibly overwrite data.

Good luck!

 

[tobyhutton1234]

Thank you that codxe works fine but it will only place into the cell range thats specified in Ancor:= .Range("D4"). It need it to go into the cell that clicked. This could be any cell in column D.

Tnanks

 

[Jerry Sullivan]

You can modify this line:

.Hyperlinks.Add Anchor:=.Range("D4"), Address:= _

To this, for the ActiveCell

.Hyperlinks.Add Anchor:=ActiveCell, Address:= _

Or this, for the Intersection of Column D and the ActiveCell's Row.

.Hyperlinks.Add Anchor:=.Cells(ActiveCell.row, 4), Address:= _

Hope this helps.

 

[tobyhutton1234]

This works great. Thank you for your time. Much appriciated.