Interior Color Multiple Columns

[gripper]

Good Afternoon,

I am working on a project as follows.

I have a excel sheet that has multiple columns with data. Focusing only on Columns("L:V" & lrow)

I want to loop through each cell in these columns with the following criteria

If Cell > 0 then highlight as green
If Cell < 0 then highlight as Red and make the text Bold and the font size equal to 14 (current default size is 11)

Each column is the same length always but that length does vary upon the data imported.

I appreciate the direction and assistance with this matter.

I want to solve this with VBA which will be used in part in other parts of this project and do not want to use the built in conditional formatting

Thank you.

 

[gripper]

Update the values will range from -15 to 15 if this helps.

 

[EXCEL MAX]

Hello Gripper,
can this code be helpful?
Test on small data size and increase size with few steps to see does work properly.
Don't forget to set sheet name.

Sub ColorCellFormatFonts()

    Dim varWS As Worksheet
    Dim varNRows As Long
    Dim varRange1 As Range, varRange2 As Range
    
    Application.ScreenUpdating = False
'set your worksheet name
    Set varWS = Worksheets("YourSheetName")
    varNRows = varWS.Range("L" & Rows.Count).End(xlUp).Row
    Set varRange2 = varWS.Range("L1:V" & varNRows)
    For Each varRange1 In varRange2
        If varRange1.Value > 0 Then
            varRange1.Interior.Color = RGB(0, 255, 0)
        End If
        If varRange1.Value < 0 Then
            With varRange1
                .Interior.Color = RGB(255, 0, 0)
                .Font.Bold = True
                .Font.Size = 14
            End With
        End If
    Next varRange1
    Application.ScreenUpdating = True

End Sub

 

[gripper]

Excel Max

Thank you for the help. This did the trick.

I appreciate it

Happy New Years!

 

[EXCEL MAX]

Thank you and Happy New Year to you.
I'm happy too if we did the trick. ?