Match only those with maximum games

[William53]

Hi All
I have the following challenge.
I want to only count the players that have played more than 'N' games (say 5 for this example) in my average calculations from the table.

Player	All Matches	Instat Index	Avg Index	Mins	Avg Mins	Shots	Passes	Avg Pass	Pass Completion	% Pass Completion	Challenges	Avg Challenges	Challenges Won	% Challenges Won
Laws	7	1571	224	639	91	2	502	72	468	93%	75	11	39	52%
Wootton	8	1824	228	773	97	2	516	65	476	92%	53	7	33	62%
Payne	7	1500	214	597	85	1	343	49	299	87%	54	8	33	61%
Sutton	8	1875	234	773	97	5	513	64	454	88%	127	16	68	54%
Piscopo	4	990	248	340	85	11	166	42	144	87%	54	14	13	24%
Rufer	6	1393	232	497	83	2	360	60	320	89%	87	15	52	60%
Lewis	7	1597	228	649	93	14	590	84	524	89%	68	10	36	53%
Sotirio	7	1502	215	551	79	19	150	21	118	79%	88	13	27	31%
Sandoval	8	1819	227	692	87	22	329	41	258	78%	102	13	33	32%
Ball	7	1588	227	634	91	17	169	24	142	84%	83	12	35	42%
Waine	3	623	208	240	80	6	47	16	37	79%	27	9	11	41%
Pennington	2	435	218	179	90	4	160	80	142	89%	33	17	17	52%
Hooper	1	198	198	95	95	2	24	24	20	83%	9	9	3	33%
McGarry	1	214	214	68	68	1	51	51	44	86%	10	10	7	70%
Fenton	2	399	200	195	98	2	132	66	113	86%	31	16	14	45%
Surman	1	221	221	100	100	0	89	89	86	97%	7	7	3	43%
Old	1	194	194	89	89	0	37	37	33	89%	9	9	3	33%

The formula below gives me the result from the whole table.

A League Scott Performance.xlsx
	O	P
32	Avg Instat Index	Piscopo
33	% Pass Completion	Surman
34	% Challenges Won	McGarry
35	Avg Pass	Surman
36	Avg Challenges	Pennington
All Players

Cell Formulas
Range	Formula
P32	P32	=INDEX(TeamStats[Player],MATCH(MAX(TeamStats[Avg Index]),TeamStats[Avg Index],0))
P33	P33	=INDEX(TeamStats[Player],MATCH(MAX(TeamStats[% Pass Completion]),TeamStats[% Pass Completion],0))
P34	P34	=INDEX(TeamStats[Player],MATCH(MAX(TeamStats[% Challenges Won]),TeamStats[% Challenges Won],0))
P35	P35	=INDEX(TeamStats[Player],MATCH(MAX(TeamStats[[Avg Pass ]]),TeamStats[[Avg Pass ]],0))
P36	P36	=INDEX(TeamStats[Player],MATCH(MAX(TeamStats[Avg Challenges]),TeamStats[Avg Challenges],0))

What do I need to add to the formula so that it only works out the max for players who have played more than 5 games?

Many thanks

 

[Fluff]

How about

+Fluff 1.xlsm
	O	P
19
20	Avg Instat Index	Sutton
21	% Pass Completion	Laws
22	% Challenges Won	Wootton
23	Avg Pass	Lewis
24	Avg Challenges	Sutton
Main

Cell Formulas
Range	Formula
P20	P20	=INDEX(SORT(FILTER(TeamStats,TeamStats[All Matches]>5),4,-1),1,1)
P21	P21	=INDEX(SORT(FILTER(TeamStats,TeamStats[All Matches]>5),11,-1),1,1)
P22	P22	=INDEX(SORT(FILTER(TeamStats,TeamStats[All Matches]>5),15,-1),1,1)
P23	P23	=INDEX(SORT(FILTER(TeamStats,TeamStats[All Matches]>5),9,-1),1,1)
P24	P24	=INDEX(SORT(FILTER(TeamStats,TeamStats[All Matches]>5),13,-1),1,1)

 

[William53]

Thank you very much Fluff, appreciated, will study the formula to understand it but works perfectly.

 

[Fluff]

You're welcome & thanks for the feedback.