Multiple Match to Different Tables to Return "Not Paid" or "Paid" Response?

[olimits7]

Hi,

I have the following formula that works to return a "Not Paid" or "Paid" response, however, I need to add another match criteria if it returns "Not Paid" to look up another data set and then either return "Not Paid" or "Paid" based on second match.

=IF(ISNA(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),"NOT PAID","PAID")

So, if "Not Paid" is returned then I would like to do another match in "[FILE-B.XLSX]DATA'!$K:$K" and then return "Not Paid" or "Paid" depending on if it matches or not.

Thank you.

 

[GuzmanServices]

Please try the following formula:

=IF(IFERROR(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),0)<>0,"PAID",IF(IFERROR(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0)),0)<>0,"PAID","NOT PAID"))

 

[Fluff]

Another option

=IF(ISNA(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),IF(ISNA(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0)),"NOT PAID","PAID"))

 

[Alex Blakenburg]

Unfortunately neither of those 2 formulas work.
@GuzmanServices has the Iferror parenthesis in the wrong place and formula can't be entered, it should be:

=IF(IFERROR(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0),0)<>0,"PAID",IF(IFERROR(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0),0)<>0,"PAID","NOT PAID"))

@Fluff doesn't have a false condition for the first if statement and if found in the FILE-A produces the result of FALSE.
Try this instead:

=IF(AND(ISNA(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),ISNA(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0))),"NOT PAID","PAID")

 

[olimits7]

I ended up using something like this and it seems to work but it's a bit long and convoluted.

=IF(IF(ISNA(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),"NOT PAID","PAID")="NOT PAID",IF(ISNA(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0)),"NOT PAID","PAID"),"PAID")

I ended up using the following formula because it was a lot cleaner than my formula. Lol.

=IF(AND(ISNA(MATCH(E1,'[FILE-A.XLSX]DATA'!$K:$K,0)),ISNA(MATCH(E1,'[FILE-B.XLSX]DATA'!$K:$K,0))),"NOT PAID","PAID")

Thank you everyone for your help with this!

 

[Fluff]

Glad we could help & thanks for the feedback.