Need some help

[jeff7188]

i been trying to type in the persons name on another page and have it pull up any codes in the cell with the dates and the points at the end. Is this possible? I have tried everything and can't get it to work. I would appreciate any help.

 

[Snakehips]

@jeff7188 I think your Excel may support TEXTJOIN function?
If so, might this help?

Book7
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF
1	Jan	1-Jan	2-Jan	3-Jan	4-Jan	5-Jan	6-Jan	7-Jan	8-Jan	9-Jan	10-Jan	11-Jan	12-Jan	13-Jan	14-Jan	15-Jan															30-Jan	Points
2	Dominique																															0
3	Mikhail															I																0.5
4	Shannon					NoNS			I			mcp																				4
5	Amanda																															0
6
Data Sheet

Book7
	A	B
1	Name	Shannon
2	Codes	NoNS, I, mcp
3	Points	4
Other Sheet

Cell Formulas
Range	Formula
B2	B2	=TEXTJOIN(", ",TRUE,INDEX('Data Sheet'!B1:AE5,MATCH(B1,'Data Sheet'!A1:A5,0),))
B3	B3	=INDEX('Data Sheet'!AF1:AF5,MATCH(B1,'Data Sheet'!A1:A5,0),)

 

[jeff7188]

Yes but I need the date as well

 

[Snakehips]

Book7
	A	B
1	Name	Shannon
2	Codes	NoNS 05-Jan, I 08-Jan, mcp 11-Jan
3	Points	4
Other Sheet

Cell Formulas
Range	Formula
B2	B2	=TEXTJOIN(", ",TRUE,IF(NOT(ISERROR(1*INDEX('Data Sheet'!B1:AE5,MATCH(B1,'Data Sheet'!A1:A5,0),)&'Data Sheet'!B$1:AE$1)),"",INDEX('Data Sheet'!B1:AE5,MATCH(B1,'Data Sheet'!A1:A5,0),)&" "&TEXT('Data Sheet'!B1:AE1,"dd-MMM")))
B3	B3	=INDEX('Data Sheet'!AF1:AF5,MATCH(B1,'Data Sheet'!A1:A5,0),)