Need to copy/paste data columns based upon date

[TsarMarkI]

Good afternoon excel gurus!

Need some help with creating a VBA macro that will allow me to do the following:
- Sheet "Tracker" contains a date in B2 and data in range I5:I33
- Sheet "Data" contains all the dates for the month in range B2:AE2
I need help with a copy/paste macro that will copy the data from "Tracker" in I5:I33 to the corresponding date on "Data" that is in cell "B2" on the "Tracker" tab

For Example:
Date in B2 on "Tracker" tab is 12/4/19
All data in range I5:I33 on "Tracker" tab is copied
Macro finds the date 12/4/19 on "Data" tab in range B2:AE2
Data is pasted in corresponding column that matches that date.

Any help with this would be greatly appreciated!

 

[DanteAmor]

How about

Sub test()
  Dim sh1 As Worksheet, sh2 As Worksheet, r As Range, f As Range
 
  Set sh1 = Sheets("Tracker")
  Set sh2 = Sheets("Data")
 
  If sh1.Range("B2").Value = "" Then
    MsgBox "put a date in B2"
    Exit Sub
  End If
 
  Set r = sh1.Range("I5:I33")
  Set f = sh2.Rows(2).Find(sh1.Range("B2").Value, , xlFormulas, xlWhole)
  If Not f Is Nothing Then
    f.Offset(1).Resize(r.Rows.Count, 1).Value = r.Value
    MsgBox "data copied"
  Else
    MsgBox "Date does not exists"
  End If

End Sub

 

[TsarMarkI]

Works perfectly, cheers

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.