Saving out a few active sheets and no PQ connections?

[AustSportingPix]

So a few people are wanting to buy my horse racing ratings. Which is great.
The problem is I don't want them to know how I work out the ratings and where I get the data from.

How can I save a copy of just the active sheets and have no PQ info in the workbook?

 

[John_w]

This macro saves the active sheets as a new .xlsx workbook, without any PQ queries or connections.

Public Sub Save_Active_Sheets_as_XLSX_Workbook()

    Dim xlsxFullName As String
    Dim ws As Worksheet
    Dim i As Long

    xlsxFullName = ThisWorkbook.Path & "\New workbook.xlsx"
    
    Application.ScreenUpdating = False
    
    'Save names of active sheets and ungroup them
    
    ReDim saveSheetNames(1 To ActiveWindow.SelectedSheets.Count) As String
    i = 0
    For Each ws In ActiveWindow.SelectedSheets
        i = i + 1
        saveSheetNames(i) = ws.Name
        ws.Select True
    Next
    
    'Copy the sheets to a new workbook
    
    ThisWorkbook.Worksheets(saveSheetNames).Copy
    
    With ActiveWorkbook
        'Delete queries
        While .Queries.Count > 0
            .Queries(1).Delete
        Wend
        'Delete connections
        While .Connections.Count > 0
            .Connections(1).Delete
        Wend
        'Suppress warning if new workbook already exists
        Application.DisplayAlerts = False
        .SaveAs Filename:=xlsxFullName, FileFormat:=xlOpenXMLWorkbook
        Application.DisplayAlerts = True
        .Close False
    End With
    
    'Regroup active sheets
    
    For i = 1 To UBound(saveSheetNames)
        ThisWorkbook.Worksheets(saveSheetNames(i)).Select False
    Next

    Application.ScreenUpdating = True
    
End Sub

 

[AustSportingPix]

Thanks Jon.
Sorry been away for a few days