On 2002-02-20 18:16, sandie713 wrote:
I have a cell that has numbers and text in it. I need to seperate the numbers from the text and put this in a seperate cell. I have tried an if statement with the isnumber function, but even when it is a number it thinks it is text. any suggestions?
Since you didn't give examples that would inform us what kind of regularity your alphanumeric entries might have, I'll consider in what follows a few possibilities:
1) xza 126 [ the alpha and num parts are separated by a space or a comma or by another delimiter ]
Use the option Data|Text To columns where you check what the delimiter is.
2) 126 xza [ the same as above ]
Again use the option Data|Text To Columns.
3) xza126, can3452, etc. [ That is, the alpha and num parts are together and the num parts is always after the alpha part ]
In B1 enter:
=SUBSTITUTE(A1,RIGHT(A1,SUMPRODUCT((LEN(A1)-LEN(SUBSTITUTE(A1,{0,1,2,3,4,5,6,7,8,9},""))))),"")
where A1 houses a target entry.
In C1 enter:
=SUBSTITUTE(A1,B1,"")+0
4) 126xza, 3452can, etc. [ That is, the alpha and num parts are together and the num parts is always before the alpha part ]
In B1 enter:
=SUBSTITUTE(A1,LEFT(A1,SUMPRODUCT((LEN(A1)-LEN(SUBSTITUTE(A1,{0,1,2,3,4,5,6,7,8,9},""))))),"")
where A1 houses a target entry.
In C1 enter:
=SUBSTITUTE(A1,B1,"")+0
5) zx67a45sad, dax765x78,etc. [ That is, alphanumeric characters are all interspersed ]
Interpreting narrowly, "I need to seperate the numbers from the text and put this in a seperate cell," as meaning delete the digits from the target entry leaving only digit-free rest behind.
Activate Insert|Name|Define;
Enter RemZeroToSeven as name in the Names in workbook box;
Enter in the Refers to box as formula:
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(Sheet1!A1,0,""),1,""),2,""),3,""),4,""),5,""),6,""),7,"")
Click OK.
Now in B1 enter:
=SUBSTITUTE(SUBSTITUTE(RemZeroToSeven,8,""),9,"")
Note. I devised the last one, the occasion being an off-line question by msvec. As might be noticed, this can also be used in cases 4 and 5!
If the entries contain numbers with decimals, the formulas above can be adapted to take care of that too.
Aladin