Simplest Way to Transfer 'All' Files, From One Folder to Another

[epoiezam]

Hi Guys,

Is there a simplest way to just transfer multiple files from one folder to another.
Prob is, file name can change, so I can't fix it in the prog.

 

[Dan_W]

The title of the thread says "all" files, and your query asks about "multiple" files. It doesn't matter that the filenames will change, but if you're only copying across multiple files, and not all, what instructions will you be giving to VBA as to which files are to be copied? Also, is the intention to move them or just copy them?

 

[epoiezam]

Hey Dan..
Sorry for the mixup.. Lets go back to the title.. All files in a folder..

 

[johnnyL]

Also, is the intention to move them or just copy them?

I think 'transfer' means move.

 

[johnnyL]

@epoiezam, you said file name can change, did you mean to say folder name? Either way, how are we to decide which one to use if it changes?

 

[Dan_W]

Hey Dan..
Sorry for the mixup.. Lets go back to the title.. All files in a folder..

This will move all files from one folder to another, unless the file already exists in the destination folder. It also tests to make sure that both folders exist, etc. otherwise you'll have errors to deal with. Is that kinda what you wanted?

Sub TestSubroutine()
    
    MoveFiles "D:\FromThisFolder\", "D:\OverToThisFolder"
    
End Sub

Sub MoveFiles(ByVal SourceDirectory As String, ByVal DestinationDirectory As String)
    
    Dim FSO             As Object
    Dim TargetFile      As Object
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    If Right(SourceDirectory, 1) <> "\" Then SourceDirectory = SourceDirectory & "\"
    If Right(DestinationDirectory, 1) <> "\" Then DestinationDirectory = DestinationDirectory & "\"
    
    If FSO.FolderExists(SourceDirectory) And FSO.FolderExists(DestinationDirectory) Then
        For Each TargetFile In FSO.getfolder(SourceDirectory).Files
            If FSO.FileExists(DestinationDirectory & TargetFile.Name) = False Then
                TargetFile.Move DestinationDirectory
            End If
        Next
    Else
        MsgBox "Error - the path details are incorrect"
        Exit Sub
    End If
    
    Set FSO = Nothing
    Set TargetFile = Nothing
End Sub

 

[Dan_W]

I think 'transfer' means move.

Well if you only 'think' that's the case, it's a good thing I checked...

 

[epoiezam]

Thanks guys.. Ok let me test Dan's code first..

 

[epoiezam]

Hey Dan, it's right on the dot.. Just what I need.. Truly appreciate it.
Not forgetting to the rest of you guys, Thank you.

 

[Dan_W]

Thank you for the feedback. Glad it works. (phew!)