Tabla posiciones - formula excel 2007

[bpxss]

Hola, Quiero que en la celda L5 aparezca un 1 si la celda S4 deja de estar "vacia" en decir que si esta vacia no tome como que el valor es cero, y lo mismo cuando las celdas S6 y S8 son llenadas con valores de manera que si las 3 tienen datos la celda L5 tendria un valor de 3. Es para calcular los partidos jugados de un equipo. Lo mismo haria con PG (patidos ganados) PP (partidos perdidos) GF (goles a favor) y GC (goles en contra).

Espero que este claro, la tabla se encuentra en el siguiente link!

gracias


http://img694.imageshack.us/i/excelv.jpg/

 

[GersonPineda]

Hola bpxss
Porque no subes un archivo (skydive por ejemplo) y dentro del archivo se mas explicito, para trabajar en el y buscar una solucion

Saludos desde Honduras

 

[bpxss]

puse el archivo en mi perfil publico en hotmail con la pregunta dentro de el.

wma0028@hotmail.com


espero que este bien asi.

saludos

 

[GersonPineda]

Debes insertar aqui, el enlace de tu archivo, que se aloja en Skydrive (no tu direccion de correo)

Saludos

 

[bpxss]

http://cid-fbe321bcbafb65ef.office.live.com/browse.aspx/.Public

 

[GersonPineda]

Estas de suerte!

Te mando un archivo que hace unos 3 años o mas aproximadamente lo elabore para un amigo

1- Hoja "formar jornadas" en la parte superior debes ingresar los nombres de tus equipos (hasta 10), en la columna F y G son para formar las llaves o sea los encuentros entre equipos (esta validado de modo que no podras repetir equipo por jornada y formato condicional por si cometes el error de armar una llave ya existente)
2- Hoja "Resultados" solo debes ingresar los goles
3- Hoja "Posiciones" es automatica
4- Hoja "Busqueda" es para que realices busqueda por jornadas o equipos
5- Hoja "Liguilla" es para un formato de liguilla, quedan los mejores 4 equipos (asi funciona el torneo local en Honduras)

Las hojas estan protegidas sin clave, algunas hojas tienen datos o tablas ocultas auxiliares, solo buscalas

Revisa cada hoja y estudiala bien, espero te sirva

LIGA HONDURAS

Saludos desde Honduras

 

[bpxss]

Muchas gracias por ayudar!

saludos

 

[justin.nc]

Espero que este claro, la tabla se encuentra en el siguiente link!

 

[cgcamal]

Hola bpxss,

Nos gusta el Fútbol verdad?

Favor seguir los pasos mencionados abajo y probar si el resultado es el deseado.

Paso 1: Definifir rangos,
1-) Definí un rango que se llame "Equipo_Local" y asocialo con "=Hoja1!$K$10:$K$32"
2-) Definí un rango que se llame "Equipo_Visitante" y asocialo con "=Hoja1!$O$10:$O$32
3-) Definí un rango que se llame "Goles_Local" y asocialo con "=Hoja1!$L$10:$L$32
4-) Definí un rango que se llame "Goles_Visitante" y asocialo con "=Hoja1!$N$10:$N$32"

Paso 2: Introducir fórmulas en "tabla auxiliar",
1-) En R5:

[COLOR=Navy]=SI(SUMA(CONTAR.SI.CONJUNTO(Equipo_Local,$Q5,Goles_Local,">=0",Goles_Visitante,">=0"),CONTAR.SI.CONJUNTO(Equipo_Visitante,$Q5,Goles_Local,">=0",Goles_Visitante,">=0"))>0,SUMA(CONTAR.SI.CONJUNTO(Equipo_Local,$Q5,Goles_Local,">=0",Goles_Visitante,">=0"),CONTAR.SI.CONJUNTO(Equipo_Visitante,$Q5,Goles_Local,">=0",Goles_Visitante,">=0")),"")[/COLOR]

2-) En S5:

[COLOR=Navy]=SI(CONTAR.BLANCO($R5)=0,SUMA(SUMAPRODUCTO(--(Equipo_Local=$Q5),--(Goles_Local<>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Local>Goles_Visitante)),SUMAPRODUCTO(--(Equipo_Visitante=$Q5),--(Goles_Local<>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Visitante>Goles_Local))),"")[/COLOR]

3-) En T5:

[COLOR=Navy]=SI(CONTAR.BLANCO($R5)=0,SUMA(SUMAPRODUCTO(--(Equipo_Local=$Q5),--(Goles_Local<>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Local=Goles_Visitante)),SUMAPRODUCTO(--(Equipo_Visitante=$Q5),--(Goles_Local<>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Visitante=Goles_Local))),"")[/COLOR]

4-) En U5:

[COLOR=Navy]=SI(CONTAR.BLANCO($R5)=0,SUMA(SUMAPRODUCTO(--(Equipo_Local=$Q5),--(Goles_Local<>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Local<goles_visitante)),sumaproducto(--(equipo_visitante=$q5),--(goles_local><>FALSO),--(Goles_Visitante<>FALSO),--(Goles_Visitante<goles_local))),"")></goles_local))),"")></goles_visitante)),sumaproducto(--(equipo_visitante=$q5),--(goles_local>[/COLOR]

Paso 3: El más dificil , arrastrar las fórmulas anteriores hasta la línea del último equipo

Probá seguir los pasos mencionados, creo funciona como se queria, sin mostrar cero si no ha habido partido aún.

Si no te funciona o encontrás algo no suficientemente claro en el procedimiento, subiría el archivo "xls" modificado
que funciona con las fórmulas mencionadas.

Espero ayude,

Saludos cordiales.

 

[cgcamal]

En el post anterior olvidé escribir las fórmulas de Goles a Favor, Goles en Contra, Diferencia y Puntos

5-) En V5:

=SI(CONTAR.BLANCO($R5)=0,SUMA(SUMAR.SI.CONJUNTO(Goles_Local,Equipo_Local,$Q5,Goles_Local,">=0",Goles_Visitante,">=0"),SUMAR.SI.CONJUNTO(Goles_Visitante,Equipo_Visitante,$Q5,Goles_Local,">=0",Goles_Visitante,">=0")),"")

6-) En W5:

=SI(CONTAR.BLANCO($R5)=0,SUMA(SUMAR.SI.CONJUNTO(Goles_Visitante,Equipo_Local,$Q5,Goles_Local,">=0",Goles_Visitante,">=0"),SUMAR.SI.CONJUNTO(Goles_Local,Equipo_Visitante,$Q5,Goles_Local,">=0",Goles_Visitante,">=0")),"")

Las últimas dos son obvias,
7-) En X5:

=SI(CONTAR.BLANCO($R5)=0,$V5-$W5,"")

8 -) En Y5:

=SI(CONTAR.BLANCO($R5)=0,SUMA($S5*3,$T5*1),"")

Saludos cordiales,