Track Item with location In/Out

[GBPPE]

I have created a Macro to track an item with barcode entry at a location with barcode entry and record the track in and track out time.
It starts by clicking the Scan Barcode button.
If the item has not already been entered it will add that item. Track in time
If the item has been entered it will add Track out time.
If the item is entered again then a new line is added with Track in time.

Now for the problem; When I try to track the item out for the second time it does not add track out time. Instead it creates another entry row with track in time.

Here are my screen shots and Thank You for your help.

 

[GBPPE]

I am adding the XL2BB to see if that helps with some answers. Thanks again.

Proof Tracking test - Copy.xlsm
	A	B	C	D
1
2	Proof Id	Location	In	Out
3	1232	r	3/1/2022 9:49 AM	3/1/2022 9:50 AM
4	456	r	3/1/2022 9:49 AM	3/1/2022 11:21 AM
5	456	t	3/1/2022 11:21 AM
6	456	t	3/1/2022 11:21 AM
7
8
Sheet1

 

[GBPPE]

Seems like I need a second range to start after the active cell so that it keeps looking for the next empty Out and fills it with a time stamp instead of creating another new line. I don't know how to do that step or where to place it in the code. Any ideas?? Something like After ActiveCell repeat the code. Kind of a loop I guess. Any ideas??

 

[NoSparks]

does this do what you're after

Sub InOut()
    Dim barcode As String, location As String
    Dim rng As Range, nextRow As Long
    
barcode = InputBox("Scan Barcode", "Proof Tracking Wizard", "")

Set rng = Sheet1.Columns("A:A").Find(What:=barcode, LookIn:=xlValues, _
    LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlPrevious, _
    MatchCase:=False, SearchFormat:=False)
' if exists
If Not rng Is Nothing Then
    If rng.Offset(, 3) = "" Then
        rng.Offset(, 3) = Now
        rng.Offset(, 3).NumberFormat = "m/d/yyy h:mm AM/PM"
        Exit Sub
    End If
End If
' if doesn't exist or already out
location = InputBox("Please Input a Location", "Proof Tracking Wizard", "")
nextRow = Sheet1.Range("A" & Rows.Count).End(xlUp).Row + 1
With Sheet1.Cells(nextRow, 1)
    .Value = barcode
    .Offset(, 1) = location
    .Offset(, 2) = Now
    .Offset(, 2).NumberFormat = "m/d/yyy h:mm AM/PM"
End With
End Sub

 

[GBPPE]

does this do what you're after

Sub InOut()
    Dim barcode As String, location As String
    Dim rng As Range, nextRow As Long
   
barcode = InputBox("Scan Barcode", "Proof Tracking Wizard", "")

Set rng = Sheet1.Columns("A:A").Find(What:=barcode, LookIn:=xlValues, _
    LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlPrevious, _
    MatchCase:=False, SearchFormat:=False)
' if exists
If Not rng Is Nothing Then
    If rng.Offset(, 3) = "" Then
        rng.Offset(, 3) = Now
        rng.Offset(, 3).NumberFormat = "m/d/yyy h:mm AM/PM"
        Exit Sub
    End If
End If
' if doesn't exist or already out
location = InputBox("Please Input a Location", "Proof Tracking Wizard", "")
nextRow = Sheet1.Range("A" & Rows.Count).End(xlUp).Row + 1
With Sheet1.Cells(nextRow, 1)
    .Value = barcode
    .Offset(, 1) = location
    .Offset(, 2) = Now
    .Offset(, 2).NumberFormat = "m/d/yyy h:mm AM/PM"
End With
End Sub

That works great! Thank You Very Very Much for the help!