Transpose row to column VBA

[drop05]

Hi i am trying to add code to transpose the row to a column where it pastes in the column M (13) until the last column used in that row 1 and put the values down in cell A2 down
I am having trouble getting the vba to go with it

  Dim FNames As Variant
  Dim Cnt As Long
  Dim Wbk As Workbook
  Dim MstWbk As Workbook
  Dim Ws As Worksheet
  'Dim wb As Workbook: Set wb = ThisWorkbook
  Dim rng As Range
  Dim I As Long
  
  Set MstWbk = ThisWorkbook
     
  FNames = Application.GetOpenFilename(FileFilter:="Excel files (*.xls*), *.xls*", MultiSelect:=False)
  If FNames = False Then Exit Sub
  Set Wbk = Workbooks.Open(FNames)
  Wbk.Worksheets("Calculation").Range("M6:BW6").Copy
  shtCompare.Cells(1, 13).PasteSpecial xlPasteValues
  Wbk.Close False

 

[DanteAmor]

I updated the macro.
Notice how I made the declaration of the variables.
You only have to adjust the name of the sheet where you are going to paste the data.

Sub transposeColumn()
  Dim FNames As Variant
  Dim Wbk As Workbook
  Dim shtCompare As Worksheet
 
  Set shtCompare = ThisWorkbook.Sheets("Sh1") 'Fit the name of the sheet where you are going to paste
    
  FNames = Application.GetOpenFilename(FileFilter:="Excel files (*.xls*), *.xls*", MultiSelect:=False)
  If FNames = False Then Exit Sub
 
  Set Wbk = Workbooks.Open(FNames)
  With Wbk.Worksheets("Calculation")
    .Range("M6", .Cells(6, .Cells(6, Columns.Count).End(1).Column)).Copy
  End With
  shtCompare.Range("A2").PasteSpecial xlPasteValues, Transpose:=True
  Wbk.Close False
End Sub

--------------
Let me know the result and I'll get back to you as soon as I can.
Cordially
Dante Amor
--------------​