type mismatch help

[cspengel]

I have a list of percentages in column J. The actual cell itself contains a VLOOKUP formula which grabs them from another sheet, but shows the percentage it pulls. Column N contains another vlookup formula, which pulls either the letter "L" or the letter "R". What I am trying to do is loop through the rows and if for example row 2 column J contains the a percentage greater than 90% and column N row 2 contains the letter L, then delete that row. This code does delete stuff(and it seems to be correct), but I get a type mismatch error on

If .Cells(x, 10).Value > 0.9 And .Cells(x, 14).Value = "L" Then

Here is the full code.

Thank you for any assistance.

Sub DeletePlayers()
Dim x As Long

Application.ScreenUpdating = True
With ActiveSheet.UsedRange
For x = 2 To Rows.Count
If .Cells(x, 10).Value > 0.9 And .Cells(x, 14).Value = "L" Then
.Rows(x).EntireRow.Delete
x = x - 1
End If
Next x
End With
Application.ScreenUpdating = False
End Sub

 

[DanteAmor]

Maybe it's because in the cells you have #N/A error.

In that case try the following code.

Notice that in the .rows.count instruction you must put the dote at the beginning, otherwise it will read all the rows of the sheet.
I highlighted the modified lines in the macro:

Sub DeletePlayers()
  Dim x As Long
 
  Application.ScreenUpdating = True
  With ActiveSheet.UsedRange
    For x = .Rows.Count To 2 Step -1
      If Not IsError(.Cells(x, 10).Value) And Not IsError(.Cells(x, 14)) Then
        If .Cells(x, 10).Value > 0.9 And .Cells(x, 14).Value = "L" Then
          .Rows(x).EntireRow.Delete
        End If
      End If
    Next x
  End With
  Application.ScreenUpdating = False
End Sub

--------------
Let me know the result and I'll get back to you as soon as I can.
Cordially
Dante Amor
--------------​

 

[cspengel]

That was it DanteAmor, Thank you so much!