Unstacking Columns

[windoz]

Hi,

I've been looking for various ways in how I can achieve the following;

Data is going from left to right from Column A to Column M, there are many more tutors and 4 tests with each and this data goes on until Column AK maybe more.

What I want to achieve is the result or example shown in Column A, Row 10 so that the data is stacked for each student per tutor.

Any ideas in how I can progress with this ?

Many thanks.

 

[queuesmef]

I suggest you add a tab to the Right of the original (Keeping Original data, in case you need to go back to it), then Copy the data (example above ) from Column I ~ M below in Column B, then copy your Rep IDs to column A. (you may want to consider a pivot table?)

 

[Fluff]

How about

Sub windoz()
   Dim Ary As Variant, Nary As Variant
   Dim r As Long, c As Long, cc As Long, nr As Long
   
   Ary = Sheets("Sheet1").Range("A1").CurrentRegion.Value2
   ReDim Nary(1 To UBound(Ary) * UBound(Ary, 2), 1 To 8)
   
   For c = 4 To UBound(Ary, 2) Step 5
      For r = 2 To UBound(Ary)
         nr = nr + 1
         Nary(nr, 1) = Ary(r, 1)
         Nary(nr, 2) = Ary(r, 2)
         Nary(nr, 3) = Ary(r, 3)
         For cc = 0 To 4
            Nary(nr, cc + 4) = Ary(r, c + cc)
         Next cc
      Next r
   Next c
   With Sheets("Sheet2")
      .Range("A1:H1").Value = Application.Index(Ary, 1, [transpose(row(1:9))])
      .Range("A2").Resize(nr, 8).Value = Nary
   End With
End Sub

Change sheet names to suit.

 

[windoz]

Fluff you are amazing!!!!!

Does exactly what I needed..This will save me hours worth of work!

Thank you so much.

 

[Fluff]

Glad to help & thanks for the feedback.