VBA code to hide blank rows

[scoha]

Is there a more efficient way to code this series of snippets which hide all blank lines between specific non contiguous ranges over a few sheets?

'Hides blank rows

    Set Rng = Range("$C$9:$C$95,$C$101:$C$198")
    
    For Each Area In Rng.Areas
        For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    
    
    Set Rng = Sheets("WI").Range("WI451Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    Set Rng = Sheets("Bits").Range("Bits451Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    
    Set Rng = Sheets("PPE").Range("PPE451Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    Set Rng = Sheets("WI").Range("WI454Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    Set Rng = Sheets("Bits").Range("Bits454Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area
    
    
    Set Rng = Sheets("PPE").Range("PPE454Names")
    
    For Each Area In Rng.Areas
       For Each Cell In Area
            If Cell.Value = "" Then Cell.EntireRow.Hidden = True
        Next Cell
    Next Area

 

[wigi]

Sure.

Sub Wigi()

    HideRows Range("C9:C95,C101:C198")
    HideRows Sheets("WI").Range("WI451Names")
    HideRows Sheets("Bits").Range("Bits451Names")
    HideRows Sheets("PPE").Range("PPE451Names")
    HideRows Sheets("WI").Range("WI454Names")
    HideRows Sheets("Bits").Range("Bits454Names")
    HideRows Sheets("PPE").Range("PPE454Names")

End Sub

Sub HideRows(rng As Range)

    On Error Resume Next
    rng.SpecialCells(4).EntireRow.Hidden = True
    On Error GoTo 0

End Sub

First test with the 'On Error ...' lines commented out. When it runs fine, you can remove the comment indicators ' in front of the lines.