VBA Delete Range of Cells in Cols A & B if Col C is Blank

[alexfooty]

In Col A I have a list of places, Col B a reference and Col C a number. There can be up to 30 rows of data.

I would like a VBA code to do the following...

Sort by Col C - smallest number first

Then delete any data in Cols A & B where Col C is blank

Bear in mind that there can be up to 30 rows of data.
I do not want to delete the entire rows as I have other data in Cols F:K that I want to keep.

Any help would be appreciated
Many thanks

 

[Fluff]

How about

Sub alexfooty()
   With Range("A1:C" & Range("A" & Rows.Count).End(xlUp).Row)
      .Sort .Columns(3), xlAscending, , , , , , xlNo
      Intersect(.EntireColumn, .Columns(3).SpecialCells(xlBlanks).EntireRow).Delete xlShiftUp
   End With
End Sub

 

[Marc L]

A VBA demonstration for starters :​

Sub Demo1()
        Dim R&
        Application.ScreenUpdating = False
    With [A1].CurrentRegion.Rows
       .Sort .Cells(3), 1, Header:=2
        R = .Cells(.Count, 3)(2).End(xlUp)(2).Row
        If R <= .Count Then .Item(R & ":" & .Count).Clear
    End With
        Application.ScreenUpdating = True
End Sub

 

[Marc L]

​

Fluff, as a reminder :​

I do not want to delete the entire rows as I have other data in Cols F:K that I want to keep.

 

[Fluff]

My code does not delete the entire row, just columns A to C

 

[alexfooty]

Fluff
Many thanks, that works exactly as I want it.
However,I am now having second thoughts about the layout of my spreadsheet and I'm thinking of moving this data to Cols E:G starting at row 23and also adding 2 more column C & D

Same rules would apply but delete C:F where Col G is blank.
Sorry to mess you about but I tried altering the VBA you supplied but with no success.

Thanks in advance

 

[Fluff]

How about

Sub alexfooty()
   With Range("C23:G" & Range("C" & Rows.Count).End(xlUp).Row)
      .Sort .Columns(5), xlAscending, , , , , , xlNo
      Intersect(.EntireColumn, .Columns(5).SpecialCells(xlBlanks).EntireRow).Delete xlShiftUp
   End With
End Sub

 

[alexfooty]

Thanks Fluff
Moved the data as described and it works perfectly. Makes my life so much easier.
Thank you so much and sorry for messing you about.
Thank also everyone who contributed

 

[Fluff]

Glad we could help & thanks for the feedback.