VBA to replace values with Yes or No

[General Ledger]

Dear All,

I am looking for a better way to change a list of values to Yes or No.

I have the below code which works fine. It examines the value on each line one at a time. This takes a long time since I have many records.

'   Convert Exclude from a Value to Text (Yes or No)
 
    Range("k2").Activate
    Do Until IsEmpty(ActiveCell)
        If ActiveCell.Value < 0 Then
            ActiveCell.Value = "Yes"
        Else:  ActiveCell.Value = "No"
        End If
        ActiveCell.Offset(1, 0).Activate
    Loop

Is there a faster way?

Thanks,

GL

 

[wigi]

Sub test()
    With Range("K2", Range("K2").End(xlDown))
        .Value = Evaluate("if(" & .Address & "<0,""yes"",""no"")")
    End With
End Sub

 

[Weaver]

Here's another

Sub val2Text()
    Dim c, lr
    On Error Resume Next
    Application.ScreenUpdating = False
    Set c = Range("K1")
    Set lr = Cells(Rows.Count, c.Column).End(xlUp)
    Set t = Range(c.Offset(1), lr)
    With c
        .AutoFilter
        .AutoFilter field:=c.column, Criteria1:="<0"
        t.SpecialCells(xlCellTypeVisible).Value = "Yes"
        .AutoFilter field:=c.column, Criteria1:="<>Yes"
        t.SpecialCells(xlCellTypeVisible).Value = "No"
        .AutoFilter
    End With
End Sub

 

[General Ledger]

Wigi and Weaver,

Thanks to both of you for excellent solutions. When I posted the question I had in mind a solution much like the one Weaver offered. However, I used Wigi's solution because of its simplicity in that I could better understand it.

GL

 

[wigi]

Thanks for the feedback.

Can you assess the speed of the macro - before and after the changes?