Numbers | Sum Unique |
40 | 150 |
50 | |
60 | |
50 | |
60 | |
40 | |
40 |
in column C5:C9999, i have values appearing as
40, 50, 60, 50, 60, 40, 40
I want total of 'unique appearance' no.
How to accomplish?
Answer for above is: 40+50+60=150
=SUM(IF(FREQUENCY(IF(ISNUMBER(C5:C9999),MATCH(C5:C9999,C5:C9999,0)),
ROW(C5:C9999)-ROW(C5)+1),C5:C9999))
A | B | C | |
---|---|---|---|
1 | Data | Result | |
2 | 20 | 140 | |
3 | 20 | ||
4 | 20 | ||
5 | 40 | ||
6 | 40 | ||
7 | 40 | ||
8 | 40 | ||
9 | 80 | ||
10 | 80 |
Array Formulas
<thead> </thead><tbody> </tbody> Note: Do not try and enter the {} manually yourself |
Branco, Aladin & Mika: Thanks. The formula WORKS. Branco's formula is SUPERB.
If you have non-numbers, empty cells or blanks, only the formula I suggested will work...
Aladin,
Yes, I have non-numbers, nulls or blanks. So I am using your formula.
Please, Can I also get the no. of 'unique appearances'?
for 40, 50, 60, 50, 60, 40, 40
Answer=3
Part B) Also how to accomplish:
40 3
50 2
60 2
40 | Unique Sum | Unique Count | |
50 | 150 | 3 | |
60 | Unique List | Occurrence Frequency | |
50 | 40 | 3 | |
50 | 2 | ||
60 | 60 | 2 | |
40 | |||
40 | |||
=ROW(Sheet1!$C$5:$C$9999)-ROW(Sheet1!$C$5)+1
=SUM(IF(FREQUENCY(IF(ISNUMBER(C5:C9999),MATCH(C5:C9999,C5:C9999,0)),Ivec),C5:C9999))
=SUM(IF(FREQUENCY(IF(ISNUMBER(C5:C9999),MATCH(C5:C9999,C5:C9999,0)),Ivec),1))
=SUM(IF(FREQUENCY(IF(C5:C9999<>"",MATCH(C5:C9999,C5:C9999,0)),Ivec),1))
=IF(ROWS($E$3:E3)<=$F$6,INDEX($C$5:$C$9999,
SMALL(IF(FREQUENCY(IF(ISNUMBER($C$5:$C$9999),MATCH($C$5:$C$9999,$C$5:$C$9999,0)),
Ivec),Ivec),ROWS($E$3:E3))),"")
=IF(ROWS($E$3:E3)<=$F$6,INDEX($C$5:$C$9999,
SMALL(IF(FREQUENCY(IF($C$5:$C$9999<>"",MATCH($C$5:$C$9999,$C$5:$C$9999,0)),
Ivec),Ivec),ROWS($E$3:E3))),"")
=IF($E8="","",COUNTIF($C$5:$C$9999,$E8))
[SIZE=2][FONT=lucida console]=IF(ROWS($E$3:E3)<=$F$6,INDEX($C$5:$C$9999,
SMALL(IF(FREQUENCY(IF(ISNUMBER($C$5:$C$9999),MATCH($C$5:$C$9999,$C$5:$C$9999,0)),
Ivec),Ivec),ROWS($E$3:E3))),"")[/FONT][/SIZE]
I am trying to copy this formula using CTRL + C but it is coming in 3 rows. How to copy the formula?
E8, control+shift+enter and copy down:
Code:[SIZE=2][FONT=lucida console]=IF(ROWS($E$3:E3)<=$F$6,INDEX($C$5:$C$9999, SMALL(IF(FREQUENCY(IF(ISNUMBER($C$5:$C$9999),MATCH($C$5:$C$9999,$C$5:$C$9999,0)), Ivec),Ivec),ROWS($E$3:E3))),"")[/FONT][/SIZE] I am trying to copy this formula using CTRL + C but it is coming in 3 rows. How to copy the formula?[/QUOTE] After you type the formula in E8, apply immediately control+shift+enter (CSE). Then drag it down as you would a non-CSE formula.