adding unique items to multiple comboboxes

[dizzydunham]

I have managed to populate a combobox on userform from a column in a table with unique items (to remove duplicates.)
I want to do the same with several other comboboxes with items from other columns in the same table.
What do I need to do to the code to make this work. as duplicating some of the below doesn't work!?

Sub RAISE_VAF_Click()

    'The Excel workbook and worksheets that contain the data, as well as the range placed on that data
    Dim wbBook As Workbook
    Dim wsSheet As Worksheet
    Dim rnData As Range
    Dim vaData As Variant               'the list, stored in a variant
    Dim ncData As New VBA.Collection    'the list, stored in a collection
    Dim lnCount As Long                 'the count used in the On Error Resume Next loop.
    Dim vaItem As Variant               'a variant representing the type of items in ncData
    'Instantiate the Excel objects.
    Set wbBook = ThisWorkbook
    Set wsSheet = wbBook.Worksheets("VAF Tracker")
    'Using Sheet1,retrieve the range of the list in Column 12 company
    With wsSheet
        Set rnData = .ListObjects("Table1").ListColumns(12).DataBodyRange
        
    End With
    'Place the list values into vaData.
    vaData = rnData.Value
    'Place the list values from vaData into the VBA.Collection.
    On Error Resume Next
        For lnCount = 1 To UBound(vaData)
        ncData.Add vaData(lnCount, 1), CStr(vaData(lnCount, 1))
    Next lnCount
    On Error GoTo 0
    'Clear the combo box (in case you ran the macro before),
    'and then add each unique variant item from ncData to the combo box.
    With UserForm2.CBXCompany.Object
        .Clear
        For Each vaItem In ncData
            .AddItem ncData(vaItem)
        Next vaItem
    End With

Thanks for any help and direction received.

 

[Fluff]

How about this

    Dim Cl As Range
    
    With CreateObject("scripting.dictionary")
        For Each Cl In Sheets("VAF Tracker").ListObjects("Table1").ListColumns(12).DataBodyRange
            If Not .exists(Cl.Value) Then .Add Cl.Value, Nothing
        Next Cl
         ComboBox1.Clear
         ComboBox1.List = Application.Transpose(.keys)
         .RemoveAll
    End With
    
    With CreateObject("scripting.dictionary")
        For Each Cl In Sheets("VAF Tracker").ListObjects("Table1").ListColumns(2).DataBodyRange
            If Not .exists(Cl.Value) Then .Add Cl.Value, Nothing
        Next Cl
         ComboBox2.Clear
         ComboBox2.List = Application.Transpose(.keys)
         .RemoveAll
    End With

This will populate combobox1 with unique values from table1 col 12 and combobox2 with uniques from col 2

 

[dizzydunham]

Thank you - The code worked like a dream -
Everyday is a learning day! - may all your dreams come true

 

[Fluff]

Glad to help & thanks for the feedback