adding vba macro

[delta59]

hey I need help writing a macro that adds 2 values in a col. and then carries the total and keeps going to row 5000. The problem is the number of rows inbetween each number is always variable and the sum needs to return to the same position(if that cant be done results can be move to col B). For example I have a set of data that looks like this, and what needs to happen. Thanks in advance

col A | col A(after macro)

21 | 21

blank | blank

blank | blank

blank | blank

35 | 56

blank | blank

-22 | 34

blank | blank

blank | blank

5 | 39

 

[AlphaFrog]

Sub Running_Total_A()

    Dim rngA As Range, a As Variant, i As Long, tot As Double
    
    Set rngA = Range("A2", Range("A" & Rows.Count).End(xlUp))
    a = rngA.Value
    
    For i = 1 To UBound(a)
        If IsNumeric(a(i, 1)) And a(i, 1) <> "" Then
            tot = tot + a(i, 1)
            a(i, 1) = tot
        End If
    Next i
    rngA.Value = a
    
End Sub

 

[Rick Rothstein]

Give this macro a try (it should execute pretty quickly)....

Sub EnterSums()
  Application.ScreenUpdating = False
  Range("B1:B" & Cells(Rows.Count, "A").End(xlUp).Row).Formula = "=SUM(A$1:A1)"
  With Columns("A").SpecialCells(xlCellTypeBlanks)
    .Offset(, 1).Value = .Value
  End With
  Columns("B").Value = Columns("B").Value
  With Columns("A").SpecialCells(xlCellTypeConstants)
    .Value = .Offset(, 1).Value
  End With
  Columns("A").Delete
  Application.ScreenUpdating = True
End Sub