Change Userform CheckBox Caption

[gman87]

I put together a userform that uses a lot (100+) of check boxes, I have made off the names match what I need them to do but I didn't change the caption to Blank...before I stated to copy

Is there a way to change all checkboxes caption to " "

Userform name is "LoadMaps"

Thanks in advance!

 

[Alan_P]

Hi gman87,

I'm not sure if there is an easy way to permanently change the captions to blank but you can do it when the userform initializes;

Private Sub UserForm_Initialize()
Dim ctrl As Control
For Each ctrl In Me.Controls
    If TypeName(ctrl) = "CheckBox" Then
        ctrl.Caption = ""
    End If
Next
End Sub

Hope this helps,
Cheers,
Alan.

 

[gman87]

Great! thanks so much!

 

[mikerickson]

To change the default caption of all checkboxes to "" (no quotes):
In the VBEditor select all the checkboxes (but no other controls), then use the Properties Window to set the Caption to "" (no quote marks, just delete everything from the input box). That should change all their captions permanently.

 

[GTO]

You can permanently change the caption by accessing Designer.

In a Standard Module:

Option Explicit
    
Sub temp()
Dim VBProj As Object ' VBIDE.VBProject
Dim VBComp As Object ' VBIDE.VBComponent
Dim Ctl As MSForms.Control
Dim WBName As String
Dim ComponentNameOrIndex As String
  
  WBName = ThisWorkbook.Name
  
  Set VBProj = Application.Workbooks(WBName).VBProject
  
  ComponentNameOrIndex = "LoadMaps"
  Set VBComp = VBProj.VBComponents(ComponentNameOrIndex)
  
  For Each Ctl In VBComp.Designer.Controls
    If TypeName(Ctl) = "CheckBox" Then
      Ctl.Caption = vbNullString
    End If
  Next
  
End Sub

Hope that helps,

Mark

PS. I forget, but you may have to have "Trust Access" ticked.

 

[GTO]

ACK! Mike's is easier