Comparing items between two data sets

[Dylan7]

Thank you for taking a look at my issue. It is a little long but I have tried to explain it as concisely as possible and will be happy to answer any questions. The included example data shows what i would like the end result to look like. I am using windows 7, Excel 2010.</SPAN>

I am looking to search the column “name” in Data Set(2) for a name from Data Set(1) to find a match. If there is a match I want to compare the associated Date from Data Set(1) to the Date in DataSet(2) and if Date(2)>Date(1) then output text "Success" in the results column.</SPAN>
If Date(2)>Date(1) is not true, then continue searching Data Set(2) for the name again until another match is made and then repeat the date test and so on until both the name and date tests are true.
I would like to do this for every name in Data Set(1)
</SPAN>

The current manual process I do right now is.</SPAN>

1. Copy Name from Data Set(1) </SPAN>
2. Find (Ctrl F) in Data Set(2) for the name</SPAN>
3. Manually determine if Date(2)>Date(1)</SPAN>
   1. If Date(2)>Date(1) is not true</SPAN>
      1. Repeat Step 2 and exclude name that was just tested</SPAN>
      2. Repeat Step 3 </SPAN>
   2. If Date(2)>Date(1) is true, Type “Success” in results column

</SPAN>
Thank you to everyone again for your time if you made it this far. I have tried a few formuals to absolutly no avail so far. I get the feeling this will need to be done in Visual Basic which i am not very good at writing in but am good at editing in.


Example Data

Data Set(1)		Data Set(2)	Results
Name	Date		Name	Date
1112A	11/1/2014		1112A	10/29/2014
1113A	12/1/2014		1105C	12/26/2014
1114B	1/5/2015		1109B	3/4/2015
1114B	11/20/2014		1113A	10/21/2014
1114A	2/6/2015		1112A	11/7/2014	Success
1115C	6/15/2015		111D	6/1/2015
1111C	11/20/2014		1315A	10/2/2014
1112B	12/11/2014		1114B	10/1/2014
			1117A	5/1/2015
			1114B	11/25/2014	Success
			1114B	2/1/2015	Success
			1113A	8/12/2014
			1114A	2/1/2015
			1116B	8/1/2015
			1115C	7/1/2015	Success
			1111C	11/27/2014	Success
			1114A	2/12/2015	Success
			1112B	3/10/2015	Success
			1113A	2/25/2015	Success

<TBODY>
</TBODY>

 

[WarPigl3t]

First of all I'd like to thank you for taking the time to be thorough in your explination as well as provide a sample dataset for me to view. I can't tell you how annoying it is when people don't do that. Now as for your two datasets, you did not specify if they are on different worksheets, so I'm going to assume that they are. Here is the code that I wrote directly from my mind. It is untested.

Sub myMacro()
    sht1 = "Sheet1"
    sht2 = "Sheet2"  [COLOR=#006400]'This one is where the results will go.[/COLOR]
    lastRow1 = Sheets(sht1).Range("A" & Rows.Count).End(xlup).Row
    lastRow2 = Sheets(sht2).Range("A" & Rows.Count).End(xlup).Row
    Sheets(sht2).Range("C2:C" & lastRow2).ClearContents  [COLOR=#006400]'might be ClearContent without the s[/COLOR]

    i = 2
    Do Until i > lastRow2
        ii = 2
        Do Until ii > lastRow1
            If Sheets(sht2).Range("A" & i).Value = Sheets(sht1).Range("A" & ii).Value AND _
                Sheets(sht2).Range("B" & i).Value > Sheets(sht1).Range("B" & ii).Value Then
                Sheets(sht2).Range("C" & i).Value = "Success"
            End If
            ii = ii + 1
        Loop
        i = i + 1
    Loop
End Sub

Take note that the code says i = 2 and ii = 2. I am assuming that the first value in your dataset 1112A is located at cell A2. If it is located in cell A3, then change 2 to 3 in both instances of the code. These are the starting points of the loops. I enjoy answering these nested loop questions because not a lot of people answer them. It's not difficult if you have enough experience doing them. You just need to imagine running through the code line by line in your head. Anyways what you asked for was very easy and I hope it works for you.

 

[hiker95]

Dylan7,

Sample raw data worksheets:

Excel 2007
	A	B
1	Name	Date
2	1112A	11/1/2014
3	1113A	12/1/2014
4	1114B	1/5/2015
5	1114B	11/20/2014
6	1114A	2/6/2015
7	1115C	6/15/2015
8	1111C	11/20/2014
9	1112B	12/11/2014
10
Data Set(1)

Excel 2007
	A	B	C
1	Name	Date
2	1112A	10/29/2014
3	1105C	12/26/2014
4	1109B	3/4/2015
5	1113A	10/21/2014
6	1112A	11/7/2014
7	111D	6/1/2015
8	1315A	10/2/2014
9	1114B	10/1/2014
10	1117A	5/1/2015
11	1114B	11/25/2014
12	1114B	2/1/2015
13	1113A	8/12/2014
14	1114A	2/1/2015
15	1116B	8/1/2015
16	1115C	7/1/2015
17	1111C	11/27/2014
18	1114A	2/12/2015
19	1112B	3/10/2015
20	1113A	2/25/2015
21
Data Set(2)

After the macro in worksheet Data Set(2):

Excel 2007
	A	B	C
1	Name	Date
2	1112A	10/29/2014
3	1105C	12/26/2014
4	1109B	3/4/2015
5	1113A	10/21/2014
6	1112A	11/7/2014	Success
7	111D	6/1/2015
8	1315A	10/2/2014
9	1114B	10/1/2014
10	1117A	5/1/2015
11	1114B	11/25/2014	Success
12	1114B	2/1/2015	Success
13	1113A	8/12/2014
14	1114A	2/1/2015
15	1116B	8/1/2015
16	1115C	7/1/2015	Success
17	1111C	11/27/2014	Success
18	1114A	2/12/2015	Success
19	1112B	3/10/2015	Success
20	1113A	2/25/2015	Success
21
Data Set(2)

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Sub FindSuccess()
' hiker95, 10/13/2014, ME811455
Dim w1 As Worksheet, w2 As Worksheet
Dim c As Range, a As Range
Dim lr As Long, n As Long, i As Long, sr As Long
Application.ScreenUpdating = False
Set w1 = Sheets("Data Set(1)")
Set w2 = Sheets("Data Set(2)")
w2.Columns(3).ClearContents
lr = w2.Cells(Rows.Count, 1).End(xlUp).Row
With w1
  For Each c In .Range("A2", .Range("A" & Rows.Count).End(xlUp))
    n = Application.CountIf(w2.Columns(1), c.Value)
    sr = 1
    If n > 0 Then
      For i = 1 To n
        Set a = w2.Range("A" & sr & ":A" & lr).Find(c.Value, LookAt:=xlWhole)
        If Not a Is Nothing Then
          If w2.Cells(a.Row, 2).Value > .Cells(c.Row, 2).Value Then
            w2.Cells(a.Row, 3).Value = "Success"
          End If
        End If
        sr = a.Row + 1
        Set a = Nothing
      Next i
    End If
  Next c
End With
With w2
  .Columns(3).AutoFit
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm

Then run the FindSuccess macro.

 

[hiker95]

Dylan7,

With the same screenshots as my reply #3, the following macro is much faster using three arrays in memory.

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

Sub FindSuccessV2()
' hiker95, 10/13/2014, ME811455
Dim a As Variant, b As Variant, o As Variant
Dim i As Long, j As Long
Dim lra As Long, lrb As Long
With Sheets("Data Set(1)")
  lra = .Cells(Rows.Count, 1).End(xlUp).Row
  a = .Range("A1:B" & lra)
End With
With Sheets("Data Set(2)")
  lrb = .Cells(Rows.Count, 1).End(xlUp).Row
  b = .Range("A1:B" & lrb)
  ReDim o(1 To lrb, 1 To 1)
End With
For i = 2 To lra
  For j = 2 To lrb
    If a(i, 1) = b(j, 1) Then
      If b(j, 2) > a(i, 2) Then
        o(j, 1) = "Success"
      End If
    End If
  Next j
Next i
With Sheets("Data Set(2)")
  .Cells(1, 3).Resize(lrb) = o
  .Columns(3).AutoFit
  .Activate
End With
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm

Then run the FindSuccessV2 macro.

 

[Dylan7]

Thanks WarPiglet, that program worked perfectly. I really appreciate your help. hiker95, i didnt try your program because the other one worked but thank you for spending time on my question also. This is a fantastic community that always amazes me with the level of support.

 

[hiker95]

Dylan7,

hiker95, i didnt try your program because the other one worked but thank you for spending time on my question also.

Thanks for the feedback.

You are very welcome.


You may be surprised by the speed of my second macro, FindSuccessV2, because it uses three arrays in memory.


And, come back anytime.