Controlling Fonts, Sizes and emphasis in a datasheet

[WildWill]

How can I control a datasheet to ensure that when other users add data to it, the data is automatically formatted to appear in (e.g.) Arial 10, Left alligned, and not bold?

 

[pbornemeier]

You can format the worksheet to that specification, but the user will be able change the formats.

If data is pasted from another source, the formatting from that source may be carried through to Excel.

In Excel 2007 and later, you can protect the formatting so the user cannot change it.

You can write code for the Worksheet_Change event that will reapply the desired formatting whenever a cell is changed.

 

[WildWill]

Awesome Phil - can you assist me with the code that you are describing?

 

[pbornemeier]

Put this code in a standard module:

Sub SetFormat()
    'many options are commented out - uncomment them if you want tem to be applied.
    With ActiveSheet.Cells
        .HorizontalAlignment = xlLeft
        '.VerticalAlignment = xlBottom
        '.WrapText = False
        '.Orientation = 0
        '.AddIndent = False
        '.IndentLevel = 0
        '.ShrinkToFit = False
        '.ReadingOrder = xlContext
        '.MergeCells = False
        With .Font
            .Name = "Arial"
            .Size = 10
            .Bold = False
            '.Strikethrough = False
            '.Superscript = False
            '.Subscript = False
            '.OutlineFont = False
            '.Shadow = False
            '.Underline = xlUnderlineStyleNone
            '.ThemeColor = xlThemeColorLight1
            '.TintAndShade = 0
            '.ThemeFont = xlThemeFontNone
        End With
    End With
End Sub

Put this code in each worksheet codepage that you want to force formats on.

Private Sub Worksheet_Change(ByVal Target As Range)
    'Will trigger if the content of cells are changed
    SetFormat
End Sub
 
Private Sub Worksheet_activate()
    'Will trigger when a different worksheet is shown
    SetFormat
End Sub

Put this code in the ThisWorkbook codepage. It will format all worksheets before saving the workbook.

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim lX As Long
    Dim sActiveSheet As String
    Application.EnableEvents = False
    Application.ScreenUpdating = False
    sActiveSheet = ActiveSheet.Name
    For lX = 1 To Worksheets.Count
        Worksheets(lX).Activate
        SetFormat
    Next
    Sheets(sActiveSheet).Activate
    Application.EnableEvents = True
    Application.ScreenUpdating = True
 
End Sub

 

[shg]

Another way, perhaps:

Private Sub Worksheet_Change(ByVal Target As Range)
    Target.Style = "Normal"
End Sub