Extract data from websites

[Lositom]

I have no idea about vba but have found this forum really helpful and have managed to put together a table where websites entered into column A are then extracted so that B returns page title, C returns h1 tag but along with this I would like D to return og:image URL from the meta properties and E to return favicon URL. Is this possible? I just can't work out how to adjust the existing code to select these final two urls from within the site's code.

Many thanks

 

[strooman]

Forget about the previous post. This board doesn't handle the "< " sign very well and it crippled the code.
New version:

Option Explicit
Sub Get_That_Data()

Dim strHTML As String, strImageUrl As String
Dim strTextTemp As String, strUrl As String
Dim LastRow As Long, i As Long
Const strTitle = "< title>"
Const strTitleEnd = "< /title>"
Const strMetaTag = "< meta property=""og:image"" content="""
Const strEnd = """ />"
Const strH1Tag = "< h1"
Const strH1End = ">"
Const strH1EndTag = "< /h1>"
    
    'As you can see I don't use CreateObject("InternetExplorer.Application")
    'Instead I use CreateObject("msxml2.xmlhttp")
    With CreateObject("msxml2.xmlhttp")
        LastRow = ActiveSheet.Cells(Rows.Count, "A").End(xlUp).Row
        
        'Loop through Column 1 from Activesheet
        For i = 2 To LastRow
        
            'I've just this strUrl for testing:
            '"http://www.metmuseum.org/art/collection/search/11122"
            strUrl = Cells(i, 1)
            .Open "GET", strUrl, False
            .send
            strHTML = .responseText
            
            'To find the elements I don't use DOM methods
            'but just search through the HTML.
            
            'Get the titel
            Cells(i, 2) = Mid(strHTML, InStr(strHTML, strTitle) + Len(strTitle), _
                            InStr(strHTML, strTitleEnd) - InStr(strHTML, strTitle) - Len(strTitleEnd) + 1)
            
            'Get the image url
            strTextTemp = Mid(strHTML, InStr(1, strHTML, strMetaTag) + Len(strMetaTag))
            Cells(i, 3) = Mid(strTextTemp, 1, InStr(strTextTemp, strEnd) - 1)
            
            'Get the h1 header
            strTextTemp = Mid(strHTML, InStr(InStr(1, strHTML, strH1Tag), strHTML, strH1End))
            Cells(i, 4) = Mid(strTextTemp, 2, InStr(strTextTemp, strH1EndTag) - 2)
            
            'Autofit
            Range(Cells(i, 1), Cells(i, 4)).Columns.AutoFit
        Next i
    End With
End Sub

Make sure you remove the space between "< t, "< m", "< h1", "< /h1" in:
Const strTitle = "< title>"
Const strTitleEnd = "< /title>"
Const strMetaTag = "< meta property=""og:image"" content="""
Const strH1Tag = "< h1"
Const strH1EndTag = "< /h1>"

Take good note of the comments.

Questions:
Please run this code. Does this example work for you?
What's the Url you fetch the data from?