Extracting a number string from an alphanumeric string of text.

[WeeZaliban]

I've been trying to pull out a middle portion of numbers from a string of text. The tricky part is the limiters on either side of the string can be found in other places at times.

For example:

AB-1234569-123.123.123.123
CD-012345-asdblkdf0934
EF-987654321-abc-123-def-987
GH-32165497-asdkfj.ekrjw
IJ-213415-afe-ierj-bne@lkasdf

The first part will always be two Alphas followed by a hyphen. The text after the numbers I need will vary in length as will the series between the two hyphens. Any help will be much appreciated.

As a fair warning, I've tried the following formulas to no avail that I thought were similar to my problem:

=MID(A1,FIND("-",A1)+1,FIND(" ",A1)-FIND("-",A1)-1
=-LOOKUP(1,-RIGHT(TRIM(LEFT(A1,FIND("-",A1)-1)),{1,2,3}))

Thanks,

WeeZ

 

[VoG]

Try

=MID(A1,4,FIND("-",SUBSTITUTE(A1,"-","~",1))-FIND("-",A1)-1)

 

[ukmikeb]

Or :-

=MID(A1,4,FIND("@",SUBSTITUTE(A1,"-","@",2))-4)

hth

 

[WeeZaliban]

@VoG - That worked perfectly! Thanks!

@ukmikeb - I'll test that one out as well.

 

[Rick Rothstein]

@VoG - That worked perfectly! Thanks!

@ukmikeb - I'll test that one out as well.

Here is another one for you to test out as well...

=MID(A1,4,FIND("-",A1,FIND("-",A1)+1)-4)

 

[Scott Huish]

Also this:

=MID(A1,4,FIND("-",A1,4)-4)

 

[Rick Rothstein]

Also this:

=MID(A1,4,FIND("-",A1,4)-4)

Good point!

 

[WeeZaliban]

Thank you very much Mike, Rick and Scott! All of the formulas provided worked perfectly.