Frames question

[harper86]

Hey
So I have a frame with 5 or 6 text boxes.
Right below this I have another frame with 5 or 6 more text boxes.
The thing I want to do is, if you are entering any text in any of the 5 or 6 text boxes the frame should change its background color to say red. Now if you go to the next frame the 1st frames bg color should go back to the original bg color and the second frames bg color should now be red.

This should also be true when you go back to frame 1.

Is there anyway to do this?

Also is there any way to change the bg color of the frame as soon as the text box becomes tabbed, like you have not input anything but the text box is selected.

Thank you very much
Hari

 

[diddi]

its a bit ironic that we all discuss the pro and cons of a mystery project whilst the person whose to benefit most, cant even be bothered to join in.

@MickG i had a great intro to class modules courtesy mikerickson, for which i have been eternally grateful. used it time and time again

 

[Colin Legg]

Based on this criterion:

The thing I want to do is, if you are entering any text

The backcolor of a frame will only change when changing the text within a textbox.


UfmTest userform class module:

Private colTextBoxEvents As Collection
Private Sub UserForm_Initialize()
 
    Dim objControl As MSForms.Control
    Dim objTextBoxEvent As clsTextboxEvent
 
    Set colTextBoxEvents = New Collection
 
    For Each objControl In Me.Controls
        If TypeOf objControl Is MSForms.TextBox Then
            Set objTextBoxEvent = New clsTextboxEvent
            Set objTextBoxEvent.TextboxToCheck = objControl
            Set objTextBoxEvent.ParentUserform = Me
            colTextBoxEvents.Add objTextBoxEvent
        End If
    Next objControl
 
End Sub

clsTextboxEvent custom class module:

Private WithEvents pTbx As MSForms.TextBox
Private pUfm As MSForms.UserForm
 
Private Enum FrameFill
    Red = &HFF&
    Grey = &H80000004
End Enum
 
Private Sub pTbx_Change()
    Dim objControl As MSForms.Control
 
    For Each objControl In pUfm.Controls
 
        If objControl Is pTbx.Parent And TypeOf objControl Is MSForms.Frame Then
            pTbx.Parent.BackColor = FrameFill.Red
        ElseIf TypeOf objControl Is MSForms.Frame Then
            objControl.BackColor = FrameFill.Grey
        End If
 
    Next objControl
End Sub
 
Public Property Set TextboxToCheck(ByRef objTextBox As MSForms.TextBox)
    Set pTbx = objTextBox
End Property
 
Public Property Set ParentUserform(ByRef objUserForm As MSForms.UserForm)
    Set pUfm = objUserForm
End Property

 

[diddi]

thats a bit clever

 

[harper86]

Hey
Again thank you for all the replies..
Colin Legg's method seems very interesting I shall try it out.
My userform is just a method for entering volumes and other information for different approaches, like NB, WB, SB and EB. So each frame captures the NB volumes and other infor and so on.
So technically what I wanted to do was if you were to tab out of the NB frame into the WB frame there should be some way to let the user know he is not entering NB volumes anymore visually. I was thinking along these lines.

Also I have another question, is there a way to set borders around a checkbox if the user tabs into it?
I mean I have 3 txtboxes and then a checkbox, so basically if he hits tab 4 times he has no way of knowing where in the form he is..Is there a way to set borders around the textbox as soon as he gets there?

 

[diddi]

you could use a transperant label with a border, and set the .visible property

 

[harper86]

At this point i feel kind of foolish...
James'W's code works perfectly fine..
Also I felt that instead of changing the bg color a altering hte spc effect woul be a slightly better

Private Sub fraNBVol_Enter()
fraNBVol.SpecialEffect = fmSpecialEffectRaised
fraWBVol.SpecialEffect = 0
fraSBVol.SpecialEffect = 0
End Sub

Private Sub fraWBVol_Enter()
fraWBVol.SpecialEffect = fmSpecialEffectRaised
fraNBVol.SpecialEffect = 0
fraSBVol.SpecialEffect = 0
End Sub

I feel like an idiot...Thank you very much..

 

[harper86]

Transparent label, **** thats a good idea...

 

[harper86]

But you cant click on the checkbox anymore because of the label.
I guess Ill just have to change the background color or something

 

[diddi]

bring the checkbox to the front
select checkbox format>order>bring to front

 

[harper86]

Oh okay that would work..
Thank you..
And we would set the bordercolor to black in what event procedure?
chkbox_enter?