function to determine next date months

[KayCee]

Hi - I'm trying to see if there's a function that can produce multiple dates in one cell. For reference, I want to create a spreadsheet for meetings based on frequency. If I have an initial meeting date, is there a function that will give me subsequent quarterly dates for future meetings?

 

[Joe4]

Welcome to the Board!

You can use the EDATE function to get the date exactly three months from now.
So, if you had a start date in cell A1, you could get the next quarter date exactly three months from that by putting this formula in cell A2:

=EDATE(A1,3)

Then, if you keep copying that down, it will give the next quarter, then the next, etc.

 

[JamesCanale]

Like this?

MrExcelPlayground6.xlsx
	A	B	C
1	Initial Meeting Date	Frequency	Future Meetings
2	1/27/2022	Quarterly	04/27/2022, 07/27/2022, 10/27/2022, 01/27/2023
3	1/1/2022	Monthly	02/01/2022, 03/01/2022, 04/01/2022, 05/01/2022, 06/01/2022, 07/01/2022
Sheet22

Cell Formulas
Range	Formula
C2:C3	C2	=TEXTJOIN(", ",TRUE,TEXT(IFS(B2="Quarterly",DATE(YEAR(EOMONTH(A2,{3,6,9,12})),MONTH(EOMONTH(A2,{3,6,9,12})),DAY(A2)),B2="Monthly",DATE(YEAR(EOMONTH(A2,{1,2,3,4,5,6})),MONTH(EOMONTH(A2,{1,2,3,4,5,6})),DAY(A2))),"mm/dd/yyy"))

EDATE is better though.

 

[Fluff]

Hi & welcome to MrExcel.
Another option

+Fluff 1.xlsm
	A	B
1	Date
2	27/01/2022	27/04/2022, 27/07/2022, 27/10/2022, 27/01/2023
3	01/03/2022	01/06/2022, 01/09/2022, 01/12/2022, 01/03/2023
Main

Cell Formulas
Range	Formula
B2:B3	B2	=TEXTJOIN(", ",,TEXT(EDATE(A2,SEQUENCE(4,,3,3)),"dd/mm/yyyy"))

 

[KayCee]

Like this?

MrExcelPlayground6.xlsx
	A	B	C
1	Initial Meeting Date	Frequency	Future Meetings
2	1/27/2022	Quarterly	04/27/2022, 07/27/2022, 10/27/2022, 01/27/2023
3	1/1/2022	Monthly	02/01/2022, 03/01/2022, 04/01/2022, 05/01/2022, 06/01/2022, 07/01/2022
Sheet22

Cell Formulas
Range	Formula
C2:C3	C2	=TEXTJOIN(", ",TRUE,TEXT(IFS(B2="Quarterly",DATE(YEAR(EOMONTH(A2,{3,6,9,12})),MONTH(EOMONTH(A2,{3,6,9,12})),DAY(A2)),B2="Monthly",DATE(YEAR(EOMONTH(A2,{1,2,3,4,5,6})),MONTH(EOMONTH(A2,{1,2,3,4,5,6})),DAY(A2))),"mm/dd/yyy"))

EDATE is better though.

I think this solution might be what I'm looking for. If there a way for this to be text instead of number? (January, April, July, October vs. 1/1/2021, 4/1/2021, etc.)

 

[KayCee]

Welcome to the Board!

You can use the EDATE function to get the date exactly three months from now.
So, if you had a start date in cell A1, you could get the next quarter date exactly three months from that by putting this formula in cell A2:

=EDATE(A1,3)

Then, if you keep copying that down, it will give the next quarter, then the next, etc.

I tried this but couldn't get it to give me multiple dates in one cell.

 

[JamesCanale]

I stole the EDATE which is just better.

MrExcelPlayground6.xlsx
	A	B	C
1	Initial Meeting Date	Frequency	Future Meetings
2	1/27/2022	Quarterly	April 27, 2022, July 27, 2022, October 27, 2022, January 27, 2023
3	1/2/2022	Monthly	February 2, 2022, March 2, 2022, April 2, 2022, May 2, 2022, June 2, 2022, July 2, 2022
Sheet22

Cell Formulas
Range	Formula
C2:C3	C2	=TEXTJOIN(", ",TRUE,TEXT(IFS(B2="Quarterly",EDATE(A2,{3,6,9,12}),B2="Monthly",EDATE(A2,{1,2,3,4,5,6})),"mmmm d, yyy"))

It's just a change to the formatting.

It gets trickly if you want to exclude weekends and holidays.

 

[Fluff]

For months only how about

+Fluff 1.xlsm
	A	B
1	Date
2	27/01/2022	April, July, October, January
3	01/03/2022	June, September, December, March
Main

Cell Formulas
Range	Formula
B2:B3	B2	=TEXTJOIN(", ",,TEXT(EDATE(A2,SEQUENCE(4,,3,3)),"mmmm"))

 

[KayCee]

=TEXTJOIN(", ",,TEXT(EDATE(A2,SEQUENCE(4,,3,3)),"mmmm"))

I think this may be exactly what I need!! Thank you!

 

[Fluff]

Glad we could help & thanks for the feedback.