hyperlinking a list of file names in excel

[Rishm]

I have a list of files below in my screenshot that I want to hyperlink. They all belong under the same folder. I am very new to VBA so I am struggling with this. They are all hyperlinked but all of the links lead to the last file "Zttach.xlsx". Is it possible to hyperlink all these files that belong to the same folder with just one macro?

Sub hyper()
Dim cell
For Each cell In Selection
ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:="C:\Users\risha\Downloads\a_few_little_tests\New folder\" & cell
Next cell
End Sub

 

[HaHoBe]

Hi Rishm,

with the codeline

ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:="C:\Users\risha\Downloads\a_few_little_tests\New folder\" & cell

you add the same link to every cell because you used

Anchor:=Selection

Maybe alter the code and try

Sub hyper_corr()
Dim cell As Range
For Each cell In Selection
  ActiveSheet.Hyperlinks.Add _
      Anchor:=cell, _
      Address:="C:\Users\risha\Downloads\a_few_little_tests\New folder\" & cell
Next cell
End Sub

You should think about replacing Selection where you would need to mark the area to work on before starting the macro with something like

Sub hyper_corr2()
Dim cell As Range
On Error Resume Next
For Each cell In ActiveSheet.UsedRange.Columns(1).SpecialCells(xlCellTypeConstants)
  ActiveSheet.Hyperlinks.Add _
      Anchor:=cell, _
      Address:="C:\Users\risha\Downloads\a_few_little_tests\New folder\" & cell
Next cell
If Err <> 0 Then
  MsgBox "Please check the range to work on, no constants found in Column A of active sheet"
End If
End Sub

or

...
For Each cell In Range("A1", Cells(Rows.Count, "A").End(xlUp))
...

The first code will work on all cells in Column A on the active sheet which are filled with constants, the sniplet will build a dynamic range with all filled cells in Column A where you might like to add a check if the cells are filled.

Ciao,
Holger