Loop thru user form controls

[FryGirl]

I have four option buttons on my user form and need to enable/disable some text boxes based on which option is selected. The code below works fine, but before I code the same for the other there option buttons, can this be reconstructed into the loop thru?

Private Sub Opt1_Click()
    If Me.Opt1 Then
        Me.txtQtr1.Enabled = True
        Me.txtQtr1e.Enabled = True
        Me.txtQtr1n.Enabled = True
        
        Me.txtQtr2.Enabled = False
        Me.txtQtr2e.Enabled = False
        Me.txtQtr2n.Enabled = False
        
        Me.txtQtr3.Enabled = False
        Me.txtQtr3e.Enabled = False
        Me.txtQtr3n.Enabled = False
        
        Me.txtQtr4.Enabled = False
        Me.txtQtr4e.Enabled = False
        Me.txtQtr4n.Enabled = False
    End If
End Sub

 

[Norie]

Can quite get the colours right, think I might have the logic the wrong way round too but give this a shot.

Sub EnableQuarter(lngQtr As Long)
Dim I As Long

    For I = 1 To 4
    
        With Me.Controls("txtQtr" & I)
            .BackColor = IIf(lngQtr = I, vbWhite, vbBlue)
            .Enabled = lngQtr = I
        End With
        
        With Me.Controls("txtQtr" & I & "e")
            .BackColor = IIf(lngQtr = I, vbWhite, vbBlue)
            .Enabled = lngQtr = I
        End With

        With Me.Controls("txtQtr" & I & "n")
            .BackColor = IIf(lngQtr = I, vbWhite, vbBlue)
            .Enabled = lngQtr = I
        End With
    Next I

End Sub

 

[FryGirl]

Thanks Norie, this does the job. Appreciate your time.