Macro To Copy Down UserID

[jo15765]

Hello - I have an excel worksheet where in Column A it has a user id, then column B it shows websites visited. It's in an unusable format currently, and I'd like to get it usable. Sample data is like this

userID     Name/site
abc123    Jack Johnson
               www.espn.com
               aol
               google
xyz789    Bob Godfrey
               msnbc
               toolscool.com
era292    Jason McKnight
               google.com
               www.google.com

What I need is to remove the actual name and add the userId to each site visited so that the excel sheet will look like this

abc123    www.espn.com
abc123    aol
abc123   google
xyz789    msnbc
xyz789    toolscool.com
era292    google.com
era292    www.google.com

What is a macro/formula/vba that will achieve this result?

 

[DanteAmor]

Try this:
Results in D2 onwards

Sub CopyUserID()
  Dim i As Long, j As Long
  Dim ant As String
  j = 2
  For i = 2 To Range("B" & Rows.Count).End(3).Row
    If ant <> Range("A" & i).Value And Range("A" & i).Value = "" Then
      Range("D" & j).Value = ant
      Range("E" & j).Value = Range("B" & i).Value
      j = j + 1
    End If
    If Range("A" & i).Value <> "" Then ant = Range("A" & i).Value
  Next
End Sub

 

[Peter_SSs]

Another option

Sub InsertIDs()
  Dim rA As Range
  
  For Each rA In Range("A2", Range("B" & Rows.Count).End(xlUp)).SpecialCells(xlBlanks).Areas
    rA.Value = rA.Cells(0, 1).Value
    Rows(rA.Row - 1).Delete
  Next rA
End Sub

Before:

jo15765.xlsm
	A	B
1	userID	Name/site
2	abc123	Jack Johnson
3		www.espn.com
4		aol
5		google
6	xyz789	Bob Godfrey
7		msnbc
8		toolscool.com
9	era292	Jason McKnight
10		google.com
11		www.google.com
Sheet1

After:

jo15765.xlsm
	A	B
1	userID	Name/site
2	abc123	www.espn.com
3	abc123	aol
4	abc123	google
5	xyz789	msnbc
6	xyz789	toolscool.com
7	era292	google.com
8	era292	www.google.com
9
10
11
Sheet1