Matching values between sheets and then replacing VBA

[sjk1193]

I need to search the 2nd column of the DATA tab and see if it matches the first column of the INDEX tab. If so I need to replace the 2nd column in the DATA tab with the value in the second column in the INDEX tab and then scroll through all rows of the DATA tab and do the same thing

example.

If Albert b, def in the DATA tab matches def, 2 in the INDEX tab then replace def in the DATA tab with 2


I have the following code so far but it doesnt seem to work

For i = 1 To 1000
For j = 2 To 1000
If Sheets("DATA").Cells(i, 2).Value = Sheets("INDEX").Cells(j, 1).Value Then
Range(Sheets("INDEX").Cells(j, 2)).Copy
Range(Sheets("DATA").Cells(i, 2)).Paste
Exit For
End If
Next j




DATA

Alan	abc
Alan	def
Alan
Alan	wer
Albert b	abc
Albert b	def
Albert b	wer
Phillips	rtt
Phillips	wer
Phillips	mnb

<tbody>
</tbody>

INDEX

abc	1
asd
wer	3
rtt	4
asdasd	6
mnb	5
sdfs
def	2
tyfyut
sdfsdf	9

<tbody>
</tbody>

 

[JLGWhiz]

give this a try.

Sub t()
Dim sh1 As Worksheet, sh2 As Worksheet, c As Range, fn As Range
Set sh1 = Sheets("DATA")
Set sh2 = Sheets("INDEX")
    For Each c In sh1.Range("B2", sh1.Cells(Rows.Count, 2).End(xlUp))
        If c <> "" Then
            Set fn = sh2.Range("A:A").Find(c.Value, , xlValues, xlWhole)
                If Not fn Is Nothing Then
                    c = fn.Offset(, 1).Value
                End If
        End If
    Next
End Sub

 

[Fluff]

How about

Sub GetMatch()
   Dim Cl As Range
   Dim Dic As Object
   
   Set Dic = CreateObject("Scripting.dictionary")
   With Sheets("index")
      For Each Cl In .Range("A2", .Range("A" & Rows.Count).End(xlUp))
         Dic.Item(Cl.Value) = Cl.Offset(, 1).Value
      Next Cl
   End With
   With Sheets("Data")
      For Each Cl In .Range("B2", .Range("B" & Rows.Count).End(xlUp))
         Cl.Value = Dic.Item(Cl.Value)
      Next Cl
   End With
End Sub

 

[sjk1193]

As well if its not in the INDEX list how would I be able to replace it with a blank ?

 

[Fluff]

My code already does that