thank you Aladin, yours looks like it works as well, but could you please help me understand what the formula is doing?

MEDIAN(IF(

**ROW(A1:A8)**>=LARGE(IF(

**ISNUMBER(A1:A8)**,

**ROW(A1:A8)**),5),IF(ISNUMBER(A1:A8),A1:A8)))

==> ROW delivers row numbers associated with the cells of the target range

MEDIAN(IF(

**{1;2;3;4;5;6;7;8}**>=LARGE(IF(

**{TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE}**,

**{1;2;3;4;5;6;7;8}**),5),IF(ISNUMBER(A1:A8),A1:A8)))

==> IF evaluates in order to fed LARGE...

MEDIAN(IF({1;2;3;4;5;6;7;8}>=LARGE({1;2;FALSE;4;FALSE;6;7;8},5),IF(ISNUMBER(A1:A8),A1:A8)))

==> LARGE states that the fifth largest row number is row 2 (where the fifth figure to include lies)

MEDIAN(IF({1;2;3;4;5;6;7;8}>=2,IF(ISNUMBER(A1:A8),A1:A8)))

==>

MEDIAN(IF({FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE},IF(

**ISNUMBER(A1:A8)**,A1:A8)))

==>

MEDIAN(IF({FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE},

**IF(****{**TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE},

**A1:A8)**))

==>

MEDIAN(IF({FALSE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE},

**{5;7;FALSE;3;FALSE;2;5;8}**))

==>

MEDIAN({FALSE;7;FALSE;3;FALSE;2;5;8})

==>

5

Expressed in a tersed manner: Mark the figures from the row on where the fifth figure is located and feed them to MEDIAN.

Hope the foregoing evaluations make clear how the formula unfolds.