multiple-row hide and unhide depending on cell

[alan myers]

	Column A	Column B	Column C	Column D
Row 1	Carriers	Hide Y/N	Start	End
Row 2	Carrier1	Y	3	51
Row 3	Carrier2	Y	60	68
Row 4	Carrier3	n	70	79
Row 5	Carrier4	n	84	86
Row 6	Carrier5	n	87	91
Row 7	Carrier6	Y	92	99
Row 8	Carrier7	Y	100	105
Row 9	Carrier8	n	110	150
Row 10	Carrier9	n	200	225
Row 11	Carrier10	Y	250	275
Row 12	Carrier11	Y	300	340
	-
	-
	-
	-
Row 196	Carrier 195	n	1234	1300

I need VBA code that when I change starting at b2 to a y, it hides the rows from c2 value to d2 value, and when I switch back to an n, it unhides them. There will be 195 cells that need to be checked.
the show hide tab is where I change b2 and I need to hide the rows on the cover sheet tab.

here is my file https://www.mediafire.com/file/aq3h8yk8dqex04n/Payroll+v1a.xlsm/file

 

[Joe4]

Go to the sheet with this grid.
Then tight-click on the sheet tab name at the bottom of your screen, select "View Code", and paste this code in the resulting VB Editor:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    Dim fr As Long
    Dim lr As Long
    
'   See if cell in cell B manually updated
    Set rng = Intersect(Target, Range("B:B"))
    If rng Is Nothing Then Exit Sub
    
'   Loop through updated cells in column B
    For Each cell In rng
'       Capture rows to update
        fr = Cells(cell.Row, "C").Value
        lr = Cells(cell.Row, "D").Value
'       Determine to hide or unhide rows
        Select Case UCase(cell)
            Case "Y"
                Sheets("Cover Sheet").Rows(fr & ":" & lr).Hidden = True
            Case "N"
                Sheets("Cover Sheet").Rows(fr & ":" & lr).Hidden = False
        End Select
    Next cell

End Sub

This should work automatically as you toggle the values in column B for "Y" to "N" and vice versa.
Note that I did not do this off of your file, which I cannot download from my current location. I did this based off of your description.
So change the sheet name in the code, if necessary.

 

[EXCEL MAX]

One more option.

Private Sub Worksheet_Change(ByVal Target As Range)

    With ActiveSheet
        If UCase(Intersect(Target, .Columns("B")).Value) = UCase("y") Then
            .Rows(Target.Offset(0, 1) & ":" & Target.Offset(0, 2)).Hidden = 1
        End If
        If Not (UCase(Intersect(Target, .Columns("B")).Value)) = UCase("y") Then
            .Rows(Target.Offset(0, 1) & ":" & Target.Offset(0, 2)).Hidden = 0
        End If
    End With
    
End Sub