Need top 5 most frequent (non-numeric) values

[yobroham]

I am trying to create a top 5 list of the most frequent values from a range. I know how to use the MODE function to get the most frequent number in a range, but I want to find the most frequent text...as well as get the next 4 most frequent. For example...

My range would be a1:a16 and I need a formula to place into d2 for the most frequent non-numerical value in the range, d3 for the second most frequent and so on...


ANY help would be greatly appreciated, excel newbie here

 

[shg]

You could copy the values to another column, use Remove Duplicates to get a unique list, and then use a COUNTIF formula to count the occurrences of each.

 

[MikeWx]

If you are still looking for a formula solution, mikerickson has one at

Here is some sample data with his formula. Copy cell D2 down for the other four values. Ties on count are not in any particular order.

Excel Workbook
	A	B	C	D
1	Fred	*	*	*
2	Ralph	*	*	Fred
3	George	*	*	Susan
4	Susan	*	*	George
5	Tom	*	*	Jeff
6	Jeff	*	*	Tom
7	Fred	*	*	*
8	Tom	*	*	*
9	Susan	*	*	*
10	Fred	*	*	*
11	George	*	*	*
12	Susan	*	*	*
13	Fred	*	*	*
14	Jeff	*	*	*
15	George	*	*	*
16	Carol	*	*	*
Sheet1

Mike

 

[Aladin Akyurek]

I am trying to create a top 5 list of the most frequent values from a range. I know how to use the MODE function to get the most frequent number in a range, but I want to find the most frequent text...as well as get the next 4 most frequent. For example...

My range would be a1:a16 and I need a formula to place into d2 for the most frequent non-numerical value in the range, d3 for the second most frequent and so on...


ANY help would be greatly appreciated, excel newbie here

Fred		5	MOST FREQ	FREQ
Ralph		2	Fred	4
George		5	George	3
Susan			Susan	3
Tom			Tom	2
Jeff			Jeff	2
Fred
Tom
Susan
Fred
George
Susan
Fred
Jeff
George
Carol

<TBODY>
</TBODY>

C1: 5 (Top 5)

C2, control+shift+enter (CSE), not just enter:

=LARGE(FREQUENCY(IF($A$1:$A$16<>"",MATCH($A$1:$A$16,$A$1:$A$16,0)),
  ROW($A$1:$A$16)-ROW($A$1)+1),C1)

C3, CSE:

=SUM(IF(FREQUENCY(IF($A$1:$A$16<>"",MATCH($A$1:$A$16,$A$1:$A$16,0)),
  ROW($A$1:$A$16)-ROW($A$1)+1)>=C2,1))

D2, CSE and copy down:

=IF($E2="","",INDEX($A$1:$A$16,SMALL(IF(FREQUENCY(IF($A$1:$A$16<>"",
  MATCH($A$1:$A$16,$A$1:$A$16,0)),ROW($A$1:$A$16)-ROW($A$1)+1)=$E2,
  ROW($A$1:$A$16)-ROW($A$1)+1),COUNTIF($E$2:E2,E2))))

E2, CSE and copy down:

=IF(ROWS($E$2:E2)<=$C$3,LARGE(FREQUENCY(IF($A$1:$A$16<>"",
  MATCH($A$1:$A$16,$A$1:$A$16,0)),ROW($A$1:$A$16)-ROW($A$1)+1),
  ROWS($E$2:E2)),"")