Select Multiple Cells Depending on Value

[Ottsel]

I have a set range from row 4 to row 696.

I attempted this, but was unsuccessful:

StartRow = 4
EndRow = 696
ColNum = 25
    For i = StartRow To EndRow
        If Cells(i, ColNum).Value <> "1" Then
            Cells(i, ColNum).EntireRow.Select
        End If
    Next i
    Selection.EntireRow.Hidden = True

I've found in my workbook selecting the cells instead of hiding each one individually speeds up the process.

Originally I was using this, but again - it takes a long time to process:

    StartRow = 4
    EndRow = 696
    ColNum = 25
    For i = StartRow To EndRow
        If Cells(i, ColNum).Value = "1" Then
            Cells(i, ColNum).EntireRow.Hidden = True
        Else
            Cells(i, ColNum).EntireRow.Hidden = False
        End If
    Next i

Overall, I want to select all the rows at once, then with the selection hide it.

Any tips, tricks or ideas are greatly appreciated!

 

[DanteAmor]

With this:
Application.ScreenUpdating = False
The execution is immediate

Try this:

Sub hiderows()
  Dim StartRow As Long, EndRow As Long, ColNum As Long, i As Long
  Dim rng As Range
 
  StartRow = 4
  EndRow = 696
  ColNum = 25
 
  Application.ScreenUpdating = False
  Rows(StartRow & ":" & EndRow).Hidden = False
  For i = StartRow To EndRow
    If Cells(i, ColNum).Value = "1" Then
      If rng Is Nothing Then Set rng = Cells(i, ColNum) Else Set rng = Union(rng, Cells(i, ColNum))
    End If
  Next i
  If Not rng Is Nothing Then
    rng.EntireRow.Hidden = True
  End If
  Application.ScreenUpdating = True
End Sub

 

[Ottsel]

With this:
Application.ScreenUpdating = False
The execution is immediate

Try this:

Sub hiderows()
  Dim StartRow As Long, EndRow As Long, ColNum As Long, i As Long
  Dim rng As Range
 
  StartRow = 4
  EndRow = 696
  ColNum = 25
 
  Application.ScreenUpdating = False
  Rows(StartRow & ":" & EndRow).Hidden = False
  For i = StartRow To EndRow
    If Cells(i, ColNum).Value = "1" Then
      If rng Is Nothing Then Set rng = Cells(i, ColNum) Else Set rng = Union(rng, Cells(i, ColNum))
    End If
  Next i
  If Not rng Is Nothing Then
    rng.EntireRow.Hidden = True
  End If
  Application.ScreenUpdating = True
End Sub

Perfect. Thank you! I had to modify slightly, but it works much faster.