Slow opening of Excel file

[assurdo]

Hello,
I've a file Excel with a pivot table and some macro. When I open this file, I need to wait some minutes (I can see the logo of Excel and the writing "Calculation ongoing (8 thread)").
Can be the presence of this macro? It uses to delete some rows.

  Dim LR3 As Long, i3 As Long


With Sheets("Import")
    LR3 = .Range("A" & .Rows.Count).End(xlUp).Row


    For i3 = LR3 To 2 Step -1
        If IsNumeric(.Range("A" & i3).Value) = False And _
        Len(.Range("A" & i3).Value) > 0 Then


        Else
            .Rows(i3).Delete
        End If
    Next i3
End With

How can I resolve this problem? Thank you.

 

[assurdo]

For sure it's that macro, because if I delete it, the workbook opens immediatly.
How can I change this code? It delete rows starting from a sheet of 3500 rows. And it delete most of them (more than 90% of the rows)

 

[RoryA]

How can I change this code?

To what?

 

[assurdo]

To what?

I mean, how to make it faster?

 

[RoryA]

Try this instead:

  Dim LR3 As Long, i3 As Long
  Dim data As Variant
    Dim rangeToDelete As Range

    With Sheets("Import")
        LR3 = .Range("A" & .Rows.Count).End(xlUp).Row
        data = .Range("A2:A" & LR3).Value
    
        For i3 = LBound(data) To UBound(data)
            If Not IsNumeric(data(i3, 1)) And _
            Len(data(i3, 1)) <> 0 Then
    
    
            Else
                If rangeToDelete Is Nothing Then
                    Set rangeToDelete = .Range("A" & i3 + 1)
                Else
                    Set rangeToDelete = Union(rangeToDelete, .Range("A" & i3 + 1))
                End If
            End If
        Next i3
    End With
    If Not rangeToDelete Is Nothing Then rangeToDelete.EntireRow.Delete

 

[assurdo]

Try this instead:

  Dim LR3 As Long, i3 As Long
  Dim data As Variant
    Dim rangeToDelete As Range

    With Sheets("Import")
        LR3 = .Range("A" & .Rows.Count).End(xlUp).Row
        data = .Range("A2:A" & LR3).Value
    
        For i3 = LBound(data) To UBound(data)
            If Not IsNumeric(data(i3, 1)) And _
            Len(data(i3, 1)) <> 0 Then
    
    
            Else
                If rangeToDelete Is Nothing Then
                    Set rangeToDelete = .Range("A" & i3 + 1)
                Else
                    Set rangeToDelete = Union(rangeToDelete, .Range("A" & i3 + 1))
                End If
            End If
        Next i3
    End With
    If Not rangeToDelete Is Nothing Then rangeToDelete.EntireRow.Delete

Grazie RoryA, ora il file Excel si apre immediatamente e fa lo stesso identico lavoro di prima. Posso chiederti in cosa si differenzia dal codice precedente? Per imparare! Grazie

 

[assurdo]

Grazie RoryA, ora il file Excel si apre immediatamente e fa lo stesso identico lavoro di prima. Posso chiederti in cosa si differenzia dal codice precedente? Per imparare! Grazie

Thank you RoryA, now the file opens immediatly. What's the difference between this code and the old one? To learn..Thank you.

 

[RoryA]

It doesn't delete one row at a time, which is always slow. It builds up a block of rows that need deleting and then deletes them all at once.

 

[assurdo]

It doesn't delete one row at a time, which is always slow. It builds up a block of rows that need deleting and then deletes them all at once.

Great, thank you RoryA!