Userform - Is there any situation when it worths using Tabstrip instead of Pages?

[Jamualson]

Seems to me that working with pages is much effective and it there is a much lower chance to make errors.

Tabstrip has only 1 advantage: you can recreate layouts really fast. But if you can bulk select all control and just throw on a new page, then this advantage seems not so attractive.

So what is the advantage so tabs are worth using? I see no advantage in practice. Thank you very much, have a nice day

 

[mikerickson]

There are no controls on a TabStrip. Ever, under any circumstances, You never have any controls on any tab of a tab strip.
There are never any option buttons on any TabStrip, so there aren't any values to save.

 

[Jamualson]

There are no controls on a TabStrip. Ever, under any circumstances, You never have any controls on any tab of a tab strip.
There are never any option buttons on any TabStrip, so there aren't any values to save.

Thx. U use a tabstrip because u want 2 tabs and same control. For example you put an option button.
Then how do you save out option button value when u change tab and option button will have another caption etc on another tab? U have to save the contents of controls on a tab before switch. Not?

 

[mikerickson]

You don't use a tabstip for that purpose.
But as an exersize, I came up with this scheme that is for 3 tabs and 4 option buttons.

' in userform's code module

Dim PreviousTabStripValue As Long

Private Sub TabStrip1_Change()
    Rem save option button values for last tab
    With TabStrip1.Tabs(PreviousTabStripValue)
        .Tag = OptionButton1.Value
        .Tag = .Tag & "," & OptionButton2.Value
        .Tag = .Tag & "," & OptionButton3.Value
        .Tag = .Tag & "," & OptionButton4.Value
        Me.Caption = .Tag
    End With

    Rem change option button captions
    OptionButton1.Caption = Split(OptionButton1.Tag, ",")(TabStrip1.Value)
    OptionButton2.Caption = Split(OptionButton2.Tag, ",")(TabStrip1.Value)
    OptionButton3.Caption = Split(OptionButton3.Tag, ",")(TabStrip1.Value)
    OptionButton4.Caption = Split(OptionButton4.Tag, ",")(TabStrip1.Value)
  
    Rem restore option button values for new tab
    With TabStrip1.SelectedItem
        OptionButton1.Value = (Split(.Tag & ",,,,", ",")(0) = "True")
        OptionButton2.Value = (Split(.Tag & ",,,,", ",")(1) = "True")
        OptionButton3.Value = (Split(.Tag & ",,,,", ",")(2) = "True")
        OptionButton4.Value = (Split(.Tag & ",,,,", ",")(3) = "True")
    End With
  
    PreviousTabStripValue = TabStrip1.Value
End Sub

Private Sub UserForm_Initialize()
    Dim i As Long
  
    Do Until TabStrip1.Tabs.Count >= 3
        TabStrip1.Tabs.Add
    Loop
  
    Rem static captions for tabstrip tabs
    With TabStrip1
        .Tabs(0).Caption = "A options"
        .Tabs(1).Caption = "B options"
        .Tabs(2).Caption = "C options"
    End With
  
    Rem captions for option buttons to change as tabstrip is changed
    OptionButton1.Tag = "option A-1,option B-1,option C-1"
    OptionButton2.Tag = "option A-2,option B-2,option C-2"
    OptionButton3.Tag = "option A-3,option B-3,option C-3"
    OptionButton4.Tag = "option A-4,option B-4,option C-4"
  
    Rem itnitalize
    For i = 0 To TabStrip1.Tabs.Count - 1
        TabStrip1.Value = i
    Next i
    TabStrip1.Value = 0
  
End Sub

The values are preserved in the .Tag property of each of the tabstrip's tabs.
I might say something about generalizing to a Class module, but nothing overides the Don't Do It, a MultiPage is the type of control you want for this.

 

[Jamualson]

You don't use a tabstip for that purpose.
But as an exersize, I came up with this scheme that is for 3 tabs and 4 option buttons.

' in userform's code module

Dim PreviousTabStripValue As Long

Private Sub TabStrip1_Change()
    Rem save option button values for last tab
    With TabStrip1.Tabs(PreviousTabStripValue)
        .Tag = OptionButton1.Value
        .Tag = .Tag & "," & OptionButton2.Value
        .Tag = .Tag & "," & OptionButton3.Value
        .Tag = .Tag & "," & OptionButton4.Value
        Me.Caption = .Tag
    End With

    Rem change option button captions
    OptionButton1.Caption = Split(OptionButton1.Tag, ",")(TabStrip1.Value)
    OptionButton2.Caption = Split(OptionButton2.Tag, ",")(TabStrip1.Value)
    OptionButton3.Caption = Split(OptionButton3.Tag, ",")(TabStrip1.Value)
    OptionButton4.Caption = Split(OptionButton4.Tag, ",")(TabStrip1.Value)
 
    Rem restore option button values for new tab
    With TabStrip1.SelectedItem
        OptionButton1.Value = (Split(.Tag & ",,,,", ",")(0) = "True")
        OptionButton2.Value = (Split(.Tag & ",,,,", ",")(1) = "True")
        OptionButton3.Value = (Split(.Tag & ",,,,", ",")(2) = "True")
        OptionButton4.Value = (Split(.Tag & ",,,,", ",")(3) = "True")
    End With
 
    PreviousTabStripValue = TabStrip1.Value
End Sub

Private Sub UserForm_Initialize()
    Dim i As Long
 
    Do Until TabStrip1.Tabs.Count >= 3
        TabStrip1.Tabs.Add
    Loop
 
    Rem static captions for tabstrip tabs
    With TabStrip1
        .Tabs(0).Caption = "A options"
        .Tabs(1).Caption = "B options"
        .Tabs(2).Caption = "C options"
    End With
 
    Rem captions for option buttons to change as tabstrip is changed
    OptionButton1.Tag = "option A-1,option B-1,option C-1"
    OptionButton2.Tag = "option A-2,option B-2,option C-2"
    OptionButton3.Tag = "option A-3,option B-3,option C-3"
    OptionButton4.Tag = "option A-4,option B-4,option C-4"
 
    Rem itnitalize
    For i = 0 To TabStrip1.Tabs.Count - 1
        TabStrip1.Value = i
    Next i
    TabStrip1.Value = 0
 
End Sub

The values are preserved in the .Tag property of each of the tabstrip's tabs.
I might say something about generalizing to a Class module, but nothing overides the Don't Do It, a MultiPage is the type of control you want for this.

Thank you very much, this is the piece of information I needed. Great example. thank you.