UserForm with MultiPage (tabs). Code to go to next tab on MultiPage

[gheyman]

Is it possible to have VBA code that will take you to the next tab in a MultiPage? If so would the button be in the MultiPage on each tab? I know you can click on each tab to change. But my users are complaining they dont know which tab they are on. So I was thinking of putting a Next button for them to click once they complete entering data on the current tab they are on.

MultiPage1
Supplier Information
Cost Source
Material
Quantity Breaks

Thanks for the help

 

[dmt32]

Hi,
Place following codes in your userforms code page & see if does what you want

Private Sub NavigateMultiPage(ByVal Direction As XlSearchDirection)

    With Me.MultiPage1
        .Value = IIf(Direction = xlPrevious, .Value - 1, .Value + 1)
        Me.cmdPrevious.Enabled = .Value > 0
        Me.cmdNext.Enabled = .Value < .Pages.Count - 1
    End With
  
End Sub

Private Sub cmdPrevious_Click()
    NavigateMultiPage xlPrevious
End Sub

Private Sub cmdNext_Click()
    NavigateMultiPage xlNext
End Sub

Rather than having buttons on each page, Maybe just placing buttons outside the Multipage will suffice?

You will need to rename controls as required

Dave

 

[DanteAmor]

'Tabs start at 0.
Private Sub CommandButton1_Click()
  MultiPage1.Value = 1  'To go to 1
End Sub

Private Sub CommandButton2_Click()
  MultiPage1.Value = 2  'To go to 2
End Sub

 

[Jaafar Tribak]

Hi,
Place following codes in your userforms code page & see if does what you want

Private Sub NavigateMultiPage(ByVal Direction As XlSearchDirection)

    With Me.MultiPage1
        .Value = IIf(Direction = xlPrevious, .Value - 1, .Value + 1)
        Me.cmdPrevious.Enabled = .Value > 0
        Me.cmdNext.Enabled = .Value < .Pages.Count - 1
    End With
 
End Sub

Private Sub cmdPrevious_Click()
    NavigateMultiPage xlPrevious
End Sub

Private Sub cmdNext_Click()
    NavigateMultiPage xlNext
End Sub

Rather than having buttons on each page, Maybe just placing buttons outside the Multipage will suffice?

View attachment 55144

You will need to rename controls as required

Dave

Nice use of the XlSearchDirection builtin Enum !

May I suggest this little modification to avoid going out of range if the first or last pages are the active ones when first loading the userform

Private Sub NavigateMultiPage(ByVal Direction As XlSearchDirection)

    With Me.MultiPage1
        .Value = Switch(Len(.Tag) = 0, .Value, Direction = xlPrevious, .Value - 1, Direction = xlNext, .Value + 1)
        .Tag = "Tagged"
        Me.cmdPrevious.Enabled = .Value > 0
        Me.cmdNext.Enabled = .Value < .Pages.Count - 1
    End With
    
End Sub

Private Sub UserForm_Initialize()
    NavigateMultiPage Direction:=Me.MultiPage1.Value
End Sub

Private Sub cmdPrevious_Click()
    NavigateMultiPage xlPrevious
End Sub

Private Sub cmdNext_Click()
    NavigateMultiPage xlNext
End Sub

 

[dmt32]

Hi,
no worries and improvements to suggestions always welcome - I constantly "raid" built-in enumeration where suitable.
Solution something I adapted from project I worked on with another here for Tab Order in Range & seemed like may work for OPs requirement.


Dave