VBA Code For Creating New Workbooks From the Copies of A Template File

[eenginar]

Hello brothers,

I have a database file which has over 1000 rows and 5 columns.

* I need a VBA code for creating a new workbook from the information of each row.
* For each row, i need a different workbook with same template.
* New workbooks will take their names form the database files C and A columns.
* 5 values (A, B,C,D,E column values of each row) will be a added to new workbooks.

Sample DATABASE and EXAMPLE TEMPLATE pic are as followings:

I hope you can help me

 

[DanteAmor]

Try this
Change "DATABASE" and "TEMPLATE" for the name of your sheeets.

Sub Creating_New_Workbooks()
  Dim sh1 As Worksheet, sh2 As Worksheet, wb2 As Workbook, i As Long
  '
  Application.ScreenUpdating = False
  Application.DisplayAlerts = False
  Set sh1 = Sheets("DATABASE")
  Set sh2 = Sheets("TEMPLATE")
  '
  For i = 2 To sh1.Range("A" & Rows.Count).End(3).Row
    sh2.Range("B5").Value = sh1.Range("A" & i).Value
    sh2.Range("B7").Value = sh1.Range("C" & i).Value
    sh2.Range("B9").Value = sh1.Range("D" & i).Value
    sh2.Range("B11").Value = sh1.Range("B" & i).Value
    sh2.Range("C6").Value = sh1.Range("E" & i).Value
    sh2.Copy
    Set wb2 = ActiveWorkbook
    wb2.SaveAs ThisWorkbook.Path & "\" & sh1.Range("C" & i).Value & "-" & sh1.Range("A" & i).Value & ".xlsx"
    wb2.Close False
  Next
  Application.ScreenUpdating = True
End Sub

 

[eenginar]

Thank you MASTER!!!

 

[eenginar]

It works perfectly ???

 

[DanteAmor]

Im glad to help you, thanks for the feedback.