VBA find next blank, display value from another cell in the same row, input value in blank

[DWriter9]

Hello all,

I have searched everywhere for this topic, but could not find anything and I am starting to think it is impossible.

Basically, I want that the code finds the next blank in column F. Upon that, a msgbox should pop up with the text value of column C of the same row that the code found the next blank.
Now, here is the tricky part, the text value of the column C on the msg box, should be able for the user to copy, the user will then paste this value on another system, which will tell him the result.
The user will come back to excels msgbox and click the correct result (A,B or None), finally code will input A or B in the found blank cell.
But if the user clicks None, the whole row should be deleted.
And so one, until there are no more blank cells in F, of course not counting the end blank cell.

The copy part is really bothering me, I am not sure if there is a way, maybe combination of Input and msg box.

Thank you in advance

 

[Legacy 143009]

Make a userform like this:

Paste this code in userform:

Private Sub CommandButton1_Click()
  Worksheets("Sheet1").writeValue (CommandButton1.Caption)
End Sub
Private Sub CommandButton2_Click()
  Worksheets("Sheet1").writeValue (CommandButton2.Caption)
End Sub
Private Sub CommandButton3_Click()
  Worksheets("Sheet1").deleteRow
End Sub
Private Sub UserForm_Initialize()
  Me.TextBox1.Locked = True
End Sub

Paste this code to Sheet1:

Public i As Long
Sub Test()
  Dim lRow As Long
  lRow = Cells(Rows.Count, "C").End(xlUp).Row
  For i = lRow To 1 Step -1
    If IsEmpty(Cells(i, "F")) Then
      UserForm1.TextBox1.Value = Cells(i, "C").Value
      UserForm1.Show
    End If
  Next
End Sub
Public Sub writeValue(buttonValue As String)
  Cells(i, "F").Value = buttonValue
End Sub
Public Sub deleteRow()
  Rows(i).EntireRow.Delete
End Sub

 

[Legacy 143009]

EDIT:
Sheet1

Public i As Long
Sub Test()
  Dim lRow As Long
  lRow = Cells(Rows.Count, "C").End(xlUp).Row
  For i = lRow To 1 Step -1
    If IsEmpty(Cells(i, "F")) Then
      UserForm1.TextBox1.Value = Cells(i, "C").Value
      UserForm1.Show
    End If
  Next
End Sub
Public Sub writeValue(buttonValue As String)
  Cells(i, "F").Value = buttonValue
  UserForm1.Hide
End Sub
Public Sub deleteRow()
  Rows(i).EntireRow.Delete
  UserForm1.Hide
End Sub

 

[DWriter9]

You are absolutely amazing, exactly what I was looking for, even better.
Works like a charm.

Thank you

 

[Legacy 143009]

I am glad it did help Thanks for the feedback!