VBA to add Multiple Charts on One Worksheet

[BBeginner]

Hi all,
I am wanting to use VBA to insert multiple charts into one worksheet in specific spaces.
I have a chart template created already as the same chart will be used for each.
Here is a photo to help explain what I'm wanting to do. I want to use the data in each row to create a bar chart for each studentID. I want the chart to be placed with the top left corner directly under the studentID.
I have around 2000 charts that need to be created. Any help is greatly appreciated!

 

[John_w]

This macro operates on the active sheet and uses the first chart on that sheet as the chart template. It copies the chart template and places it below each StudentID row and sets the chart name, title and source data using that student's data.

Rather than adding all 2000 charts, for test purposes the macro loop is For studentRow = 2 To 50 Step 13, so adding only 4 charts. To add all 2000 charts, comment out or delete that line and remove the comment character at the start of 'For studentRow = 2 To lastStudentRow Step 13.

Public Sub Add_Student_Charts()

    Dim studentRow As Long, lastStudentRow As Long
    Dim chartTemplate As ChartObject
    Dim studentChart As ChartObject
    
    Application.ScreenUpdating = False
    
    With ActiveSheet
        Set chartTemplate = .ChartObjects(1)
        lastStudentRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        For studentRow = 2 To 50 Step 13                'Testing - only 4 students
        'For studentRow = 2 To lastStudentRow Step 13   'All students
            Set studentChart = chartTemplate.Duplicate.Chart.Parent
            studentChart.Top = .Range("A" & studentRow + 1).Top
            studentChart.Left = .Range("A" & studentRow + 1).Left
            studentChart.Name = "Chart Student " & .Range("A" & studentRow).Value
            studentChart.Chart.SetSourceData Source:=.Range("B1:F1,B" & studentRow & ":F" & studentRow)
            studentChart.Chart.ChartTitle.Text = .Range("A" & studentRow).Value
        Next
    End With
    
    Application.ScreenUpdating = True
    
End Sub

Run this macro if you need to delete all the student charts, leaving only the chart template (the first chart on the sheet):

Public Sub Delete_Student_Charts()

    Dim i As Long

    With ActiveSheet
        For i = .ChartObjects.Count To 2 Step -1
            .ChartObjects(i).Delete
        Next
    End With
    
End Sub