Multiple criteria with Multiple Match

[dtman85]

Data Table:

Date	Store	Agent
July 1 2017	Anderson	100
July 1 2017	Nashville	99
July 1 2017	Kentucky	100
July 2 2017	Maine	100
July 2 2017	Riverdale	99
July 4 2017	Alabama	100
July 4 2017	South Carolina	100
July 4 2017	Anderson	99

<tbody>
</tbody>

Result:

Agent	July 1 2017	July 2 2017
100	Anderson/Kentucky	Maine

<tbody>
</tbody>

I want to find the Agent with the name of the stores by date. Index match will yield the first store but I can't figure out how to find the second store by omitting the first value with multiple criteria. Is it possible to get multiple stores result within one cell?

 

[Scott T]

Excel 2010
	A	B	C	D
1	Date	Store	Agent
2	7/1/2017	Anderson	100
3	7/1/2017	Nashville	99
4	7/1/2017	Kentucky	100
5	7/2/2017	Maine	100
6	7/2/2017	Riverdale	99
7	7/4/2017	Alabama	100
8	7/4/2017	South Carolina	100
9	7/4/2017	Anderson	99
10
11
12	Agent	7/1/2017	7/2/2017	7/4/2017
13	100	Anderson	Maine	Alabama
14		Kentucky		South Carolina
Sheet1

Cell Formulas
Range	Formula
B13	{=IF(ROWS(B$13:B13)>COUNTIFS($A$2:$A$9,B$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=B$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(B$13:B13))))}
B14	{=IF(ROWS(B$13:B14)>COUNTIFS($A$2:$A$9,B$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=B$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(B$13:B14))))}
C13	{=IF(ROWS(C$13:C13)>COUNTIFS($A$2:$A$9,C$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=C$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(C$13:C13))))}
C14	{=IF(ROWS(C$13:C14)>COUNTIFS($A$2:$A$9,C$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=C$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(C$13:C14))))}
D13	{=IF(ROWS(D$13:D13)>COUNTIFS($A$2:$A$9,D$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=D$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(D$13:D13))))}
D14	{=IF(ROWS(D$13:D14)>COUNTIFS($A$2:$A$9,D$12,$C$2:$C$9,$A$13),"",INDEX($B$2:$B$9,SMALL(IF($C$2:$C$9=$A$13,IF($A$2:$A$9=D$12,ROW($B$2:$B$9)-ROW($B$2)+1)),ROWS(D$13:D14))))}
Press CTRL+SHIFT+ENTER to enter array formulas.