Thanks Thanks:  0
Likes Likes:  0
Page 1 of 2 12 LastLast
Results 1 to 10 of 11

Thread: #N/A Error of to many arguments

  1. #1
    Board Regular
    Join Date
    Sep 2005
    Location
    USA
    Posts
    57
    Post Thanks / Like
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    Default #N/A Error of to many arguments

    The following formula works well as long as the vlookup finds data. I need to work an IFNA into this formula, but since I have an "IF" condition before the vlookup, I can't add ifna in front of the vlookup or I will get an error of to many arguments. Am I missing a simple work-around on this?

    =IF(B3="","",IF(C3="","Enter Name",IF('PFP Goals'!$C$39=1,(VLOOKUP($C3,'Jan-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=2,(VLOOKUP($C3,'Feb-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=3,(VLOOKUP($C3,'Mar-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=4,(VLOOKUP($C3,'Apr-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=5,(VLOOKUP($C3,'May-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=6,(VLOOKUP($C3,'Jun-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=7,(VLOOKUP($C3,'Jul-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=8,(VLOOKUP($C3,'Aug-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=9,(VLOOKUP($C3,'Sep-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=10,(VLOOKUP($C3,'Oct-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=11,(VLOOKUP($C3,'Nov-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=12,(VLOOKUP($C3,'Dec-Pay Paste'!$C$4:$Z$498,3,FALSE)),0))))))))))))))

    Thanks,

    Jeff

  2. #2
    Board Regular
    Join Date
    Jun 2014
    Location
    Oakland, CA
    Posts
    5,044
    Post Thanks / Like
    Mentioned
    39 Post(s)
    Tagged
    2 Thread(s)

    Default Re: #N/A Error of to many arguments

    Hi,

    Wrap your entire formula within IFNA:

    =IFNA(your formula,value if na)

  3. #3
    Board Regular
    Join Date
    Sep 2005
    Location
    USA
    Posts
    57
    Post Thanks / Like
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    Default Re: #N/A Error of to many arguments

    I guess I am not following. This say to many arguments too.


    =IFNA(B6="","",IF(C6="","Enter Name",IF('PFP Goals'!$C$39=1,(VLOOKUP($C6,'Jan-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=2,(VLOOKUP($C6,'Feb-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=3,(VLOOKUP($C6,'Mar-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=4,(VLOOKUP($C6,'Apr-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=5,(VLOOKUP($C6,'May-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=6,(VLOOKUP($C6,'Jun-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=7,(VLOOKUP($C6,'Jul-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=8,(VLOOKUP($C6,'Aug-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=9,(VLOOKUP($C6,'Sep-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=10,(VLOOKUP($C6,'Oct-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=11,(VLOOKUP($C6,'Nov-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=12,(VLOOKUP($C6,'Dec-Pay Paste'!$C$4:$Z$498,3,FALSE)),0)))))))))))))),0)

    Thanks,

    Jeff

  4. #4
    Board Regular
    Join Date
    Jun 2014
    Location
    Oakland, CA
    Posts
    5,044
    Post Thanks / Like
    Mentioned
    39 Post(s)
    Tagged
    2 Thread(s)

    Default Re: #N/A Error of to many arguments

    No, Wrap your ENTIRE ORIGINAL formula within IFNA:

    =IFNA(IF(B3="","",IF(C3="","Enter Name",IF('PFP Goals'!$C$39=1,(VLOOKUP($C3,'Jan-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=2,(VLOOKUP($C3,'Feb-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=3,(VLOOKUP($C3,'Mar-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=4,(VLOOKUP($C3,'Apr-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=5,(VLOOKUP($C3,'May-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=6,(VLOOKUP($C3,'Jun-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=7,(VLOOKUP($C3,'Jul-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=8,(VLOOKUP($C3,'Aug-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=9,(VLOOKUP($C3,'Sep-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=10,(VLOOKUP($C3,'Oct-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=11,(VLOOKUP($C3,'Nov-Pay Paste'!$C$4:$Z$498,3,FALSE)),IF('PFP Goals'!$C$39=12,(VLOOKUP($C3,'Dec-Pay Paste'!$C$4:$Z$498,3,FALSE)),0))))))))))))))
    ,"")
    Last edited by jtakw; May 7th, 2018 at 06:14 PM.

  5. #5
    Board Regular
    Join Date
    Mar 2018
    Location
    Japan
    Posts
    227
    Post Thanks / Like
    Mentioned
    1 Post(s)
    Tagged
    0 Thread(s)

    Default Re: #N/A Error of to many arguments

    I may be mistaken, but I believe the max number of Nested IF statements is 7. Currently you have 12. You would most likely do better by utilizing hidden "helper columns" which would enable you to separate your IF statements. You could then reference back to the hidden columns using another IF formula. Let me know if you need assistance with this or if it what I said doesn't make sense.
    Helper columns are the way of the future!

    All recommendations/work is completed in Excel 2013.
    ------
    - forum use guidelines, forum rules and terms of use
    - Try searching for your answer first, see how
    - Read the FAQs
    - List of BB codes

  6. #6
    Board Regular
    Join Date
    Sep 2005
    Location
    USA
    Posts
    57
    Post Thanks / Like
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    Default Re: #N/A Error of to many arguments

    Awesome. Thank you!

    Jeff

  7. #7
    Board Regular
    Join Date
    Jun 2014
    Location
    Oakland, CA
    Posts
    5,044
    Post Thanks / Like
    Mentioned
    39 Post(s)
    Tagged
    2 Thread(s)

    Default Re: #N/A Error of to many arguments

    You're welcome.

  8. #8
    Board Regular
    Join Date
    Jun 2014
    Location
    Oakland, CA
    Posts
    5,044
    Post Thanks / Like
    Mentioned
    39 Post(s)
    Tagged
    2 Thread(s)

    Default Re: #N/A Error of to many arguments

    Quote Originally Posted by Robby19 View Post
    I may be mistaken, but I believe the max number of Nested IF statements is 7.
    That's true for Excel versions prior to 2010, since Excel 2010, you can nest up to 64 levels.

    https://support.office.com/en-us/art...c-aa8bbff73be2
    Last edited by jtakw; May 7th, 2018 at 06:38 PM.

  9. #9
    MrExcel MVP Eric W's Avatar
    Join Date
    Aug 2015
    Location
    Bountiful, UT
    Posts
    7,858
    Post Thanks / Like
    Mentioned
    34 Post(s)
    Tagged
    3 Thread(s)

    Default Re: #N/A Error of to many arguments

    Even though 64 levels are allowed, generally speaking, a formula that long is hard to read and understand. You can condense that entire formula to something like this:

    =IFNA(IF(B3="","",IF(C3="","Enter Name",VLOOKUP($C3,INDIRECT("'"&TEXT(DATE(2000,'PFP Goals'!$C$39,1),"mmm")&"-Pay Paste'!$C$4:$Z$498"),3,FALSE))),"")

    using the INDIRECT to select the sheet instead of 12 levels of IFs.
    Cheers,
    Eric

    When you eliminate the impossible, whatever remains, however improbable, must be the truth.

    -Posting guidelines, forum rules, terms of use, FAQs, BB codes, See how to search the forum
    -Post a screen shot with the HTML Maker

  10. #10
    Board Regular
    Join Date
    Mar 2018
    Location
    Japan
    Posts
    227
    Post Thanks / Like
    Mentioned
    1 Post(s)
    Tagged
    0 Thread(s)

    Default Re: #N/A Error of to many arguments

    Quote Originally Posted by jtakw View Post
    That's true for Excel versions prior to 2010, since Excel 2010, you can nest up to 64 levels.
    You learn something new everyday. Thank you.
    Helper columns are the way of the future!

    All recommendations/work is completed in Excel 2013.
    ------
    - forum use guidelines, forum rules and terms of use
    - Try searching for your answer first, see how
    - Read the FAQs
    - List of BB codes

Some videos you may like

User Tag List

Tags for this Thread

Like this thread? Share it with others

Like this thread? Share it with others

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •