VBA: Save current workbook with new name

[FryGirl]

I need to save the current workbook with a new name and then run a macro on just the new workbook. I would also like to close the new workbook, but keep the original workbook open.

Here is what I have so far. The new workbook is getting saved with the macro running on the new workbook, but both workbook close. Should I name the current workbook in the code?

The current workbook is Master.xlsm

Sub Save_it()
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim FilePath As String
    FilePath = ActiveWorkbook.Path & Application.PathSeparator
    Set Destwb = ActiveWorkbook
    With Destwb
        .SaveAs FilePath & "Input.xlsm", FileFormat:=52
        Call DeleteSheets
        .Close SaveChanges:=True
    End With
End Sub

Sub DeleteSheets()
    Application.DisplayAlerts = False
    Sheets("Sheet2").Delete
    Sheets("Sheet3").Delete
    Application.DisplayAlerts = True
End Sub

 

[NdNoviceHlp]

Not sure why your removing sheets in the new wb's? Anyways, it would be quicker to use copyfile than saving. Then new files can be opened and then run the macro from within the new file. Here's a link. HTH. Dave
https://www.mrexcel.com/forum/excel...but-permission-denied.html?highlight=copyfile

 

[rlv01]

Not tested

Sub Save_it()
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim WS As Worksheet
    Dim FilePath As String
    FilePath = ActiveWorkbook.Path & Application.PathSeparator
    ThisWorkbook.SaveCopyAs (FilePath & "Input.xlsm")
    Set Destwb = Application.Workbooks.Open(Filename:=FilePath & "Input.xlsm")
    With Destwb
        For Each WS In .Worksheets
            Application.DisplayAlerts = False
            Select Case WS.Name
            Case "Sheet2", "Sheet3"
                WS.Delete
            End Select
            Application.DisplayAlerts = True
        Next WS
        .Close SaveChanges:=True
    End With
End Sub

 

[FryGirl]

Thank you rlv01. That is absolutely perfect. Just want I was needing.

 

[NdNoviceHlp]

Sweet riv01! The alerts might come outside the loop?. I'll save a copy of that. Thanks. Dave
ps. frygirl I'm glad U arrive at a solution