AVERAGEIFS for last X records in a customer list?

[GaryV]

I have a dataset that looks a bit like this:

Cust A	1/1/18	345
Cust A	2/1/18	634
Cust A	3/1/18	567
Cust B	11/1/18	1209
Cust B	12/1/18	1340
Cust B	1/1/18	1500
Cust B	2/1/18	1654
Cust B	3/1/18	1567
Cust C	2/1/18	423
Cust C	3/1/18	450
Cust D	3/1/18	1690

<tbody>
</tbody>

The record count can vary by customer. I'm looking to average the 3rd column's numbers, for up to the last 3 rows, by customer.

I have a separate list of unique customer ID's and I've been experimenting with AVERAGEIFS, Offset, etc., but can't seem to get the logic correct.

Could I kindly ask for an experts view on this and for any recommendations on a solution?

Many thanks!!
G

 

[dave2018]

Hi, set up your shet like the image here:

https://drive.google.com/open?id=1DK5lnq7osu8VQxBaWFNm2IJOYmJyZQb6

In F3, put the following array formula (Make sure to enter the formula with CTRL+SHIFT+ENTER, so that curly brackets {} appear at either end in the formula bar on top of the screen. You can't put type them in yourself!)

=AVERAGE(INDEX(C1:C11,N(IF(1,LARGE(IF(--(A1:A11=F1)*C1:C11<>0,ROW(A1:A11)),ROW(INDIRECT("1:"&F2,1)))))))

 

[Aladin Akyurek]

Control+shift+enter, not just enter:

=AVERAGE(IF(ROW(C2:C12)>=LARGE(IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),IF(C2:C12>0,ROW(C2:C12)))),
    MIN(3,COUNTIFS(A2:A12,"Cust A",C2:C12,">0"))),IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),IF(C2:C12>0,C2:C12)))))

 

[dave2018]

That's an interesting way how to do it. but why do you need the isnumber, and also not use cell refrences for the criteria?

Also, it would be interesting to see the difference in calculation time between the 2

 

[Aladin Akyurek]

Control+shift+enter, not just enter:

=AVERAGE(IF(ROW(C2:C12)>=LARGE(IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),IF(C2:C12>0,ROW(C2:C12)))),
    MIN(3,COUNTIFS(A2:A12,"Cust A",C2:C12,">0"))),IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),IF(C2:C12>0,C2:C12)))))

By the way, The >0 test is probably not required.

=AVERAGE(IF(ROW(C2:C12)>=LARGE(IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),ROW(C2:C12))),
     MIN(3,COUNTIFS(A2:A12,"Cust A"))),IF(A2:A12="Cust A",IF(ISNUMBER(C2:C12),C2:C12))))

 

[GaryV]

Can't thank you enough Dave and Aladin, I'll take a poke at this and see if my fumbling fingers can get your code into my spreadsheet! thanks again!!!

G

 

[GaryV]

Thanks Gents! Dave I wound up using your snippet for its ability to handle all customer names. I had a few challenges with the array formula and realized it didn't like having a header row at the top. But I have it functioning just as I want it, thanks again!!!

G

 

[dave2018]

Can't you just change the refrences to row 2?

 

[Aladin Akyurek]

Thanks Gents! Dave I wound up using your snippet for its ability to handle all customer names. I had a few challenges with the array formula and realized it didn't like having a header row at the top. But I have it functioning just as I want it, thanks again!!!

G

Let F2 or any other cell house a condition (customer) like Cust A and adjust the formula you are given:

=AVERAGE(IF(ROW($C$2:$C$12)>=LARGE(IF($A$2:$A$12=F2,IF(ISNUMBER($C$2:$C$12),ROW($C$2:$C$12))),
    MIN(3,COUNTIFS($A$2:$A$12,F2))),IF($A$2:$A$12=F2,IF(ISNUMBER($C$2:$C$12),$C$2:$C$12))))

which has "the ability to handle all customer names" as you put it.

 

[GaryV]

Thanks, I probably missed something in my translation and will check again today, but the averages did not calc correctly when I had a header row...